MINISTÉRIO DA EDUCAÇÃO

INSTITUTO FEDERAL DE EDUCAÇÃO, CIÊNCIA E TECNOLOGIA DO PIAUÍ – IFPI

CAMPUS CAMPO MAIOR
CURSO TÉCNICO EM INFORMÁTICA (2019.02 – MÓDULO II)
DISCIPLINA: ALGORITMOS II – PROFESSOR: NAIRON S. VIANA
Aluno (A): ________________________________________

Atividade Prática – Algoritmos – Estudo Digirido (05/11/2019)

PARTE I – VETORES

Questão 1

Construa um algoritmo para declarar um vetor de 10 posições com números inteiros,

cada posição correspondendo à um valor real. Armazene os seguintes números reais,
em ordem: 5.0, 3.0, 10, 5.5, 8.5, 4.2, 7.1, 8.8, 7.9, 6.0. Mostre os valores das posições
(índices) ímpares do vetor, calcule e mostre a soma dos seus elementos.

algoritmo "Q1"
var
v: vetor[1..10] de real
i: inteiro
soma: real
inicio

v[1] <- 5.0

v[2] <- 3.0
v[3] <- 10.0
v[4] <- 5.5
v[5] <- 8.5
v[6] <- 4.2
v[7] <- 7.1
v[8] <- 8.8
v[9] <- 7.9
v[10] <- 6.0
soma <-0
para i de 1 ate 10 faca
se (i%2=1)entao
escreval("Valor da posição ímpar ", v[i])
fimse
soma <- soma + v[i]
fimpara
escreval("A soma de todos os elementos é: ", soma)
fimalgoritmo

Questão 2

Construa um algoritmo para declarar 2 vetores de 5 posições cada. O primeiro vetor deve
armazenar os valores de uma lista de frutas: "Maçã", "Abacaxi", "Mamão", "Melão",
"Limão". O segundo vetor deve armazenar os seguintes valores reais: 4.50, 5.50, 3.50,
2.50, 4.0. O algoritmo deve mostrar, para cada posição o nome de uma fruta e o seu
preço. Ao final o algoritmo deve mostrar o valor total da lista de compras.

algoritmo "Q2"
var
frutas: vetor[1..5] de caractere
precos: vetor[1..5] de real
soma: real
i: inteiro
inicio
frutas[1] <- "Maçã"
frutas[2] <- "Abacaxi"
frutas[3] <- "Mamão"
frutas[4] <- "Melão"
frutas[5] <- "Limão"
precos[1] <- 4.50
precos[2] <- 5.50
precos[3] <- 3.50
precos[4] <- 2.50
precos[5] <- 4.00

i<-1
soma <-0
enquanto (i<=5) faca
escreval("Posição ",i)
escreval("Nome da fruta ", frutas[i])
escreval("Preço da fruta ", precos[i])
escreval("*****************************")
soma <- soma + precos[i]
i <- i+1
fimenquanto
escreval("O valor total é: ", soma)
fimalgoritmo
Questão 3
Você foi contratado para construir um algoritmo para controlar a quantidade de faturas de
cartão de crédito de Marcos ao longo de 6 meses. Em cada mês, marcos gasta com os
seguintes itens: item A – Alimentação; item B – Vestuário; item C – Lazer; item D –
Viagens. Em cada mês o algoritmo deve receber os valores gastos por marcos com cada
item, calcular e armazenar em um vetor (de 6 posições) o valor total da fatura do
cartão em cada mês, mostrar o valor da fatura no mês, bem como armazenar em
outro vetor os meses de 1 a 6 (Janeiro a Junho). Após armarzenar os dados, o
algoritmo deve mostrar apenas os valores totais gastos no primeiro e no último mês
considerado. Em seguida, o algoritmo deve mostrar quanto Marcos gastou com cartão de
crédito nos últimos 6 meses.

algoritmo "Questao3"
var
faturas: vetor[1..6] de real
meses: vetor[1..6] de caractere
total, itemA, itemB, itemC, itemD, soma: real
i: inteiro
inicio
// Armazendo os valores dos meses
meses[1] <- "Janeiro"
meses[2] <- "Fevereiro"
meses[3] <- "Março"
meses[4] <- "Abril"
meses[5] <- "Maio"
meses[6] <- "Junho"
// Parte I - Receber os valores em cada mês
escreval("Recebendo os valores das faturas: ")
i<-1
soma <-0
enquanto (i<=6) faca
escreval("Mês: ",meses[i])
escreval("Digite gasto de alimentação (itemA): ")
leia(itemA)
escreval("Digite gasto de vestuário (itemB): ")
leia(itemB)
escreval("Digite gasto de Lazer (itemC): ")
leia(itemC)
escreval("Digite gasto de viagens (itemD): ")
leia(itemD)
total <- itemA + itemB + itemC + itemD
 escreval("Total da fatura em ", meses[i], ": ", total)
faturas[i] <- total
i <- i+1
fimenquanto
// Mostrar valor total gasto no primeiro mês
escreval("Valor gasto no primeiro mês: ", faturas[1])
escreval("Valor gasto no último mês: ", faturas[6])
// Calcular o valor total gasto nos 6 meses
// Somar todas as faturas
soma <- 0
para i de 1 ate 6 faca
soma <- soma + faturas[i]
fimpara
escreval("Valor total das faturas nos 6 meses: ", soma)

fimalgoritmo

Questão 4

Construa um algoritmo para declarar um vetor de números inteiros e armazenar os

seguintes valores: 4, 7, 9, 2, 8, 3, 6, 1, 12 e 10. Em seguida, realize os seguintes
procedimentos, em ordem:

a. Percorra o vetor e mostre todos os seus elementos e posições (utlize a estrutura de

repetição REPITA..ATE)
b. Percorra novamente o vetor e mostre apenas os elementos que são ímpares (utilize a
estrutura de repetição ENQUANTO..FACA)
c. Percorra novamente o vetor, calcule e mostre a soma e a média (utilize a estrutura de
repetição ENQUANTO..FACA)
d. Percorra novamente o vetor, mostre o maior elemento (utilize REPITA..ATE)
e. Percorra novamente o vetor, mostre o menor elemento (utilize REPITA..ATE)

algoritmo "Questao4"
var
v: vetor[1..10] de inteiro
i, maior, menor: inteiro
soma, media: real
inicio
// Armazendo os valores no vetor de inteiros
v[1] <- 4
v[2] <- 7
v[3] <- 9
v[4] <- 2
v[5] <- 8
v[6] <- 3
v[7] <- 6
v[8] <- 1
v[9] <- 12
v[10] <- 11

// Letra a)
escreval("Mostrando os elementos do vetor...")
i<-1
repita
escreval("Elemento da posição ", i, ": ")
escreval(v[i])
i <- i+1
ate(i>10)
// Letra b)
escreval("Mostrando os elementos ímpares...")
i<-1
enquanto (i<=10) faca
se (v[i]%2 = 1) entao
escreval("Posição ", i, ": ")
escreval(v[i])
fimse
i <- i+1
fimenquanto
// Letra c)
escreval("Calculando a soma e a média")
i<-1
soma<-0
enquanto (i<=10) faca
soma <- soma + v[i]
i <- i+1
fimenquanto
media <- soma/10
escreval("A soma dos elementos é: ", soma)
escreval("A média dos elementos é: ", media)
 // Letra d)
escreval("Calculando o maior elemento:")
i<-1
maior <- v[1]
repita
se(v[i]>maior)entao
maior <- v[i]
fimse
i <- i+1
ate(i>10)
escreval("O maior elemento do vetor é: ", maior)
// Letra e)
escreval("Calculando o menor elemento:")
i<-1
menor <- v[1]
repita
se(v[i]<menor)entao
menor <- v[i]
fimse
i <- i+1
ate(i>10)
escreval("O menor elemento do vetor é: ", menor)

fimalgoritmo

Questão 5

Construa um algoritmo para armazenar os valores de salários e nomes de 5

empregados, da seguinte forma: crie um vetor de real, para armazenar cada um dos 5
salários; em seguida, crie um vetor de caractere, para armazenar os 5 nomes. Os
valores serão armazenados para cada uma das 5 posições dos dois vetores. Observe
que para cada posição do vetor deve corresponder um valor de salário e um valor de
nome. Em seguinda responda:
a. Utilize comandos de entrada para inserir os valores nos 2 vetores.
b. Mostre todos os salários dos empregados e os nomes.
c. Mostre o nome e salário do último empregado
d. Mostre o nome e salário do empregado que possui maior salário;
e. Mostre o nome e salário do empregado que possui menor salário;
f. Mostre a média dos salários dos empregados.

algoritmo "Questao5"
var
salarios: vetor[1..5] de real
nomes: vetor[1..5] de caractere
i: inteiro
salMenor, salMaior, soma, media: real
nomeMenor, nomeMaior: caractere
inicio
// Letra a)
escreval("******** a) Lendo os valores ********")
para i de 1 ate 5 faca
escreval("Posição ", i)
escreval("Digite o nome do empregado: ")
leia(nomes[i])
escreval("Digite o salário do empregado: ")
leia(salarios[i])
fimpara
// Letra b)
escreval("******** b) Mostrando os valores ********")
i<-1
enquanto (i<=5) faca
escreval("Posição ", i)
escreval("Nome do empregado: ", nomes[i])
escreval("Slário do empregado: ", salarios[i])
i<- i+1
fimenquanto

// Letra c)
escreval("******** c) Último empregado: ********")
escreval("Nome do último empregado: ", nomes[5])
escreval("Slário do último empregado: ", salarios[5])

// Letra d)
escreval("********d) Maior Salário ********")
i<-1
salMaior <- salarios[1]
nomeMaior <- nomes[1]
enquanto (i<=5) faca
se (salarios[i]>salMaior)entao
salMaior <- salarios[i]
 nomeMaior <- nomes[i]
fimse
i<- i+1
fimenquanto
escreval("Empregado com maior salário: ")
escreval("Nome: ", nomeMaior)
escreval("Salário: ", salMaior)
// Letra e)
escreval("********e) Menor Salário ********")
i<-1
salMenor <- salarios[1]
nomeMenor <- nomes[1]
enquanto (i<=5) faca
se (salarios[i]<salMenor)entao
salMenor <- salarios[i]
nomeMenor <- nomes[i]
fimse
i<- i+1
fimenquanto
escreval("Empregado com menor salário: ")
escreval("Nome: ", nomeMenor)
escreval("Salário: ", salMenor)
// Letra f)
escreval("********f) Média dos salários ********")
i<-1
soma<-0
repita
soma <- soma + salarios[i]
i<- i+1
ate(i>5)
media <- soma/5
escreval("A média é: ", media)

fimalgoritmo