Introducere in asamblare

(Categoria Limbaje de programare, Autor Cristian Botau)

Coninut:
Limbajul de asamblare: avantaje si dezavantaje in folosirea lui
Avantaje ale limbajului de asamblare
Dezavantaje ale limbajului de asamblare
Notiuni de baza ale limbajului de asamblare
Registrii
Registrii de uz general
Registrii de segment si index
Registrii speciali
Flagurile microprocesorului
Instructiunile de baza ale microprocesorului 8086
Instructiunea MOV
Instructiuni aritmetice. Instructiunile ADD, SUB, INC , DEC
Instructiuni pe biti. Instructiunile AND, TEST, OR, XOR, NOT
Instructiunile PUSH/POP
Instructiunea C MP
Jump-urile neconditionate (JMP) si jump-urile conditionate
Instructiunea LOOP
Instructiunea INT
Transcrierea unor instructiuni C /PASC AL in asamblare
IF cond THEN instr
IF cond THEN instr1 ELSE instr2
DO { inst } WHILE
Program demonstrativ
Linkuri
Doua cuvinte conclusive...

Acest articol prezinta un limbaj mai putin folosit : limbajul de asamblare. Este folosit de cele mai multe ori pentru
marirea vitezei de rulare a programelor. In prima sectiune sunt prezentate cateva avantaje / dezavantaje in folosirea
acestui limbaj, iar ulterior sunt definite notiunile elementare ce trebuie stiute inainte de a trece la tratarea limbajului
propriu-zis. De asemenea, sunt prezentate cateva intructiuni si transcrieri ale unor structuri din C/Pascal in limbaj de
asamblare. In final sunt comparati timpii de executie intre varianta pascal si varianta assembler ale unei proceduri de
Bubble Sort.
Limbajul de asamblare pe mediul x86 exista in doua tipuri de sintaxe :
Intel
AT&T
Sintaxa depinde de compilatorul folosit. De exemplu: Turbo Assembler (inclus in pachetul BC3.1) si Netw ide Assembler
(NASM) folosesc sintaxa Intel. GAS (folosit de GCC) foloseste sintaxa AT&T.
Nota: In GCC se poate folosi si sintaxa Intel, detalii aici .
O alta diferenta importanta este felul in care este interpretat cuvantul cheie asm in diferite compilatoare C/C++.
De exemplu, aceeasi instructiune in mediul Borland, si GCC cu cele 2 sintaxe :
Borland C 3.1 (sau TASM)
1 asm { mov ax, bx }; ?

GCC (sintaxa AT&T)

1 asm ("mov %bx, %ax"); ?

GCC (sintaxa Intel)

1 asm (".intel_syntax noprefix\n\t" ?
2 "mov ax, bx");
Exemplele prezentate in acest articol sunt scrise in sintaxa Intel.
Limbajul de asamblare : avantaje si dezavantaje in folosirea lui
Desi este unul dintre cele mai vechi limbaje de programare, limbajul de asamblare este incorporat si in cele mai noi
compilatoare cum ar fi Visual C++ si Delphi. Codul de asamblare este foarte apropiat de codul executabil al
programelor, asamblorul avand rolul de a codifica instructiunile din limbaj de asamblare in cod masina.
In prezent, limbajul de asamblare este din ce in ce mai putin folosit in scrierea programelor, deoarece compilatoarele
de ultima generatie au functiile cele mai folosite de programatori deja scrise si optimizate in limbaj de asamblare (gen
memmove, memset / fillchar, etc.) incluse in unit-uri si biblioteci. Bineinteles, daca se doreste atingerea unor timpi de
executie foarte mici, folosirea limbajului de asamblare este preferabila (cand avem algoritmul de complexitate optima).

Avantaje ale limbajului de asamblare

Viteza foarte mare de executie a programelor (unele programe scrise si optimizate in asamblare au viteza de
executie pana la 5-10 de ori mai mare decat cele scrise in C sau Pascal);
Marimea codului executabil este foarte mica;
Ajuta utilizatorul sa inteleaga mai bine cum functioneaza microprocesorul si sa scrie programe eficiente si in High
Level Languages.
Dezavantaje ale limbajului de asamblare
nu este portabil; un program scris pentru calculatoare IBM PC nu va rula pe un Apple Macintosh (difera unele
instructiuni);
un program in asamblare este mai greu de scris si ia mai mult timp decat un program scris in Pascal sau C;
un program scris in asamblare este mai greu de depanat;
Majoritatea compilatoarelor din prezent permit programatorului sa scrie anumite parti de cod sau subprograme in
asamblare, astfel incat programatorul sa poata scrie in asamblare doar partea din program care se executa de cele
mai multe ori, programul ruland astfel mult mai rapid. Sunt si compilatoare dedicate exclusiv limbajului de asamblare,
cum ar fi TASM - Turbo Assembler (il gasiti in directorul BP/Bin), MASM - Microsoft Assembler, etc.
Pentru a scrie o secventa de limbaj de asamblare intr-un program C se foloseste cuvantul rezervat asm :
1 asm { instructiuni in asamblare }; ?

iar in pascal :
1 asm ?
2 cod asamblare
3 end.

Notiuni de baza ale limbajului de asamblare

Registrii
Limbajul de asamblare este foarte apropiat de codul executabil, deci pentru ca programatorul sa fie capabil sa scrie
codul in asamblare trebuie sa cunoasca modul in care functioneaza microprocesorul si modul in care acesta executa
instructiunile.
Toate operatiile aritmetice/logice/acces la memorie se fac prin intermediul registrilor. Registrii microprocesorului sunt
asemanatori variabilelor (pot fi initializati cu anumite valori, se pot efectua operatii asupra lor, pot fi accesati
(cititi/modificati)).
Registrii microprocesorului sunt clasificati in mai multe categorii :
registri de uz general : eax, ebx, ecx, edx si subregistrii lor;
registri segment : cs (code segment), ds (data segment), es (extra segment), ss (stack segment) - sunt folositi
pentru adresarea memoriei in cazul modelului de memorie segmentat
registrii index : esi, edi (source index, destination index);
registri speciali : ebp, esp, ip;

Registrii de uz general sunt folositi in executia operatiilor aritmetice si logice. Registrii de segment si cei index sunt
folositi in adresarea memoriei, iar cei speciali sunt folositi de microprocesor si S.O. pentru rularea programelor.
Registrii de uz general
Acestia sunt :
eax - numit si "accumulator" - acesta este cel mai folosit in executarea operatiilor aritmetice (adunare, scadere,
inmultire, impartire);
ebx - numit si "base" - acesta registru este folosit pentru adresarea indirecta a memoriei;
ecx - numit si "count" - acest registru este folosit mai ales in cadrul "buclelor" (in instructiunile repetitive : for/
w hile do/ do w hile/ repeat until);
edx - numit si "data" - retine anumite variabile, si este folosit impreuna cu eax in executarea operatiei "div",
impartire intreaga (avand rolul de a retine restul impartirii).
Dupa cum ati observat, fiecare registru general are o functie specifica, insa oricare din ei pot fi folositi si la operatii
aritmetice/logice, adresare memorie sau ca si variabile.
Registrii precedati de prefixul " e" sunt pe 32 de biti, deci pot fi tratati ca si variabile unsigned long/signed long
(doubleword). Acestia pot fi folositi si ca registri pe 16 biti (word) sau pe 8 biti (byte) prin intermediul "subregistrilor" :
ax, bx, cx, dx (reprezinta w ord-ul nesemnificativ = cel din dreapta)., ah, bh, ch, dh (byte-ul cel mai semnificativ al ax, bx,
cx, dx), al, bl, cl, dl(registrii pe 8 biti).
Registrii de segment si index
Acesti registri sunt folositi la adresarea memoriei.
De exemplu
Avem variabila void *x;(x : pointer in pascal);
pentru modelul de memorie segmentata, in adresarea memoriei adresate de x se folosesc intructiunile (vezi
"Intructiunile de baza ale unui microprocesor 8086") :
1 // es:[di] va accesa adresa pointata de x; ?
2 les di, x
3 // se copiaza in ax primul word
4 // de la adresa es:[di]
5 mov ax, es:[di]
6 // se copiaza in al cel de-al 3-lea byte
7 // de la adresa es:[di]
8 mov al, es:[di+2]
Parantezele drepte se refera la zona de memorie adresata de registru.
Exemplu :
" [esi]" se refera la valoarea aflata la adresa de memorie cu offset-ul esi, iar " esi" se refera la valoarea stocata in
registrul esi;
daca esi = 100 atunci [esi] va reprezenta valoarea care se afla la adresa cu offset-ul 100, iar esi va reprezenta
valoarea 100.

Va sfatuiesc sa NU incercati sa modificati urmatorii registri : cs (care contine segmentul la care se afla incarcat codul
executabilului, ss contine segmentul de memorie in care se afla stiva sistemului).

Registrii speciali
Sunt folositi foarte rar in scrierea efectiva a programelor, deci nu veti accesa prea des acesti registri.De exemplu, ip
(instruction pointer) care retine adresa (de fapt offset-ul) la care se afla instructiunea care urmeaza sa fie executata.
Flagurile microprocesorului
Flag-urile microprocesorului sunt asemanatoare unor variabile boolene. Cu ajutorul lor putem afla rezultatul unei
comparatii sau daca o operatie a produs "overflow ", etc. Aceste flag-uri nu pot fi accesate direct ca si registrii, ci
testarea daca un flag este activat se face prin intermediul "jump"-urilor conditionate.(vezi instructiunea cmp).

Exemplu :
Fie ax = 1. Decrementarea lui ax cu 1 va duce la activarea flagului numit Zero-Flag.(rezultatul operatiei a fost 0).
Fie ax = 65535 (0xFFFF). Incrementarea lui ax cu 2 va duce la setarea flagului numit Overflow -Flag (rezultatul operatiei
nu "incape" in 16 biti);
Instructiunile de baza ale microprocesorului 8086
Sunt folosite urmatoarele prescurtari :
reg8/ reg16/ reg32 - se refera la registri pe 8/16/32 biti;
imm8/ imm16/ imm32 - se refera la valori imediate (constante);
mem8/ mem16/ mem32 - zona memorie de memorie sau variabile pe 8/16/32 biti;
Instructiunea MOV
Sintaxa:
mov dest, source // echivalenta cu dest = source
Variante:
mov reg8/16/32, mem8/16/32
mov reg8/16/32, reg8/16/32
mov mem8/16/32, reg8/16/32
mov reg8/16/32, imm8/16/32
mov mem8/16/32, imm8/16/32
Descriere:
Instructiunea copiaza o valoare dintr-o locatie in alta locatie. Aceasta locatie poate fi zona de memorie, variabila,
registru. De retinut este ca nu exista variante ale instructiunii care copiaza direct dintr-o zona de memorie in alta.
Flaguri afectate:
Instructiunea mov nu modifica nici un flag.
Restrictii:
Ambii operanzi trebuie sa aiba aceeasi marime. De exemplu pentru ultima varianta a instructiunii mov trebuie
specificata marimea zonei de memorie. Instructiunea "mov [bx], 0" nu este corecta deoarece compilatorul nu stie ce
vrea sa faca instructiunea: sa copieze valoarea 0 in byte-ul, in w ord-ul sau in doublew ord-ul de la adresa bx. Astfel
variantele corecte sunt:
1 mov byte ptr [bx], 0 ?
2 mov word ptr [bx], 0
3 mov dword ptr [bx], 0
Exemplu:
1 mov ax, 3 // ax = 3 ?
2 mov bx, ax // bx = ax
Instructiuni aritmetice. Instructiunile ADD, SUB, INC, DEC
Sintaxa:
add dest, source // echivalenta cu dest+=source
sub dest, source // echivalenta cu dest-=source
inc dest // echivalenta cu dest++
dec dest // echivalenta cu dest--
Variante:
add(sub) reg8/16/32, mem8/16/32
add(sub) reg8/16/32, reg8/16/32
add(sub) mem8/16/32, reg8/16/32
add(sub) reg8/16/32, imm8/16/32
add(sub) mem8/16/32, imm8/16/32
Descriere:
Instructiunea " add" este folosita pentru a aduna doua valori, " sub" pentru a scadea o valoare din alta, " inc" -
incrementarea unei variabile, " dec" - decrementarea unei variabile (registru/memorie).

Flaguri afectate:
carry flag - pentru "signed overflow "
overflow flag - pentru overflow
sign flag - activat daca rezultatul este negativ
zero flag - activat daca rezultatul operatiei a fost 0
parity flag - este setat in functie de paritatea rezultatului
Restrictii:
Destinatia trebuie sa aiba aceeasi marime ca si sursa.
Exemplu:
1 mov ax, 3 // ax = 3 ?
2 add bx, ax // bx = ax+3
Instructiuni pe biti. Instructiunile AND, TEST, OR, XOR, NOT
Sintaxa:
and dest, source // echivalenta cu dest&=source
test dest, source // dest & source
or dest, source // echivalenta cu dest|=source
xor dest, source // echivalenta cu dest^=source
not dest // ~dest
Variante:
Pentru " and", " or", " test", " xor" sunt ca si cele de la " add". Pentru " not" avem doua variante :

not reg8/16/32
not mem
Descriere:
Executa operatiile pe biti corespunzatoare. Instructiunea test (non-destructive and) este asemanatoare lui and, dar
nu afecteaza rezultatul ci doar flagurile.
Flaguri afectate:
Instructiunea " not" nu afecteaza nici un flag.
Flagurile afectate de celalalte instructiuni sunt :
carry, overflow - le dezactiveaza
sign flag - este copiat bitul cel mai semnificativ din rezultat (semnul rezultatului, de fapt)
zero flag - activat daca rezultatul operatiei a fost 0
parity flag - este setat in functie de paritatea rezultatului
Restrictii:
Destinatia trebuie sa aiba aceeasi marime ca si sursa.
Instructinile OR/XOR/INC/DEC modifica flag-urile microprocesorului: Carry(numai ADD/SUB), Overflow, Zero, Parity.

Exemplu:
1 mov ax, 5 // ax = 3 ?
2 test ax, 1 // daca (ax & 1)
3 jz @skip // daca ax este nu este impar sari la @skip
4 // executa instructiuni
5 @skip
6 and bx, FFFEh // bx = bx & 0xFFFE (se sterge bitul cel mai nesemnificativ)
Instructiunile PUSH/POP
Descriere:
Aceste instructiuni sunt folosite pentru accesarea stivei sistemului. Instructiunea PUSH pune pe stiva sistemului o
valoare, iar instructiunea POP extrage valoarea din varful stivei.
Sintaxa:
push val
pop val
Variante:
push reg8/16/32
pop reg8/16/32
Exemplu:
1 @lp: ?
2 push cx // salvam valoarea cx
3 ... // prelucreaza datele, se poate modifica cx
4 pop cx // scoate de pe stiva valoarea cx
5 dec cx
6 jnz @lp // daca (cx != 0) atunci sari inapoi la @lp
Instructiunea CMP

Descriere:
Compara doua valori si seteaza flag-urile microprocesorului cu rezultatele compararii. De cele mai multe ori este
folosita in combinatie cu jump-urile (vezi mai jos).
Sintaxa:
cmp val1, val2
Variante:
cmp reg8/16/32, reg8/16/32
cmp reg8/16/32, imm8/16/32
cmp mem8/16/32, reg8/16/32
cmp mem8/16/32, imm8/16/32
Jump-urile neconditionate (JMP) si jump-urile conditionate (JE, JNE, JB, JBE, JA, JAE, JZ, JNZ)
Aceste instructiuni sunt folosite pentru generarea instructiunilor If /w hile do /do w hile /repeat /for.Sunt asemanatoare
instructiunii goto din C/Pascal.
Sintaxa:
instructiune label
JE * "sare" cu executia programului la label daca flag-ul equality este setat;
JNE * "sare" cu executia programului la label daca flag-ul equality nu este setat;
JB * "sare" cu executia programului la label daca flag-ul below este setat;
JBE * "sare" cu executia programului la label daca flag-ul below sau flagul equality este setat;
JA * "sare" cu executia programului la label daca flag-ul below nu este setat;
JAE * "sare" cu executia programului la label daca flag-ul equality este setat sau flag-ul below nu este setat;
JZ * "sare" cu executia programului la label daca flag-ul zero este setat;
JNZ * "sare" cu executia programului la label daca flag-ul zero nu este setat;
JMP * "sare" cu executia programului la label;
Exemplu:
 1 mov ax, 1 ?
2 @loop :
3 instr1
4 instr2
5 *
6 inc ax
7 // compara ax cu valoarea 10 si seteaza flagurile
8 cmp ax, 10
9 // daca ax != 10 sari inapoi la @loop
10
11 jne @loop
12
13 == code(cpp) |instr1
14 jmp @label1
15 instr2
16 instr3
17 @label1 :
In ultimul exemplu instr2 si instr3 nu vor fi executate deoarece inaintea lor se afla instructiunea jump care face ca
programul sa sara cu executia la instructiunea imediat urmatoare etichetei "label1".
Instructiunea LOOP
Instructiunea "loop" este folosita de obicei in transcrierea for-urilor si a buclelor.
Sintaxa:
loop label
Descriere:
Echivalenta cu :
1 dec ecx (sau dec cx) ?
2 jz label
Instructiunea INT
Descriere:
Instructiunea INT apealeaza o intrerupere.
Sintaxa:
INT nr_intrerupere (un numar cuprins intre 0 si 255);
Intreruperile opresc programul din rulare, executa un anumit cod si apoi permit continuarea rularii programului. Cu
ajutorul apelului intreruperilor aplicatia poate sa comunice cu sistemul de operare, si cu unele componente hardw are
ale calculatorului (mouse-ul, tastatura, imprimanta, etc). Fiecare intrerupere are asociat un numar.
Exemple:
0x9 : intreruperea pentru tastatura;
0x10 : intreruperea care ofera serviciile BIOS pentru accesul la placa video;
0x21 : intreruperea sistemului de operare DOS;
0x33 : intreruperea pentru mouse;
In DOS pentru initializarea mouse-ului se va apela functia numarul 0 a intreruperii 0x33 :
1 asm ?
2 {
3 mov ax, 0
4 // seteaza registrul ax cu valoarea 0 pentru ca
5 // driverul ce gestioneaza intreruperea 0x33
6 //sa stie ca trebuie sa initializeze mouse-ul
7 int 0x33
8 }
Pentru afisarea mouse-ului :
 1 asm ?
2 {
3 mov ax, 1
4 int 0x33
5 }
Pentru ascunderea cursorului de la mouse :
1 asm ?
2 {
3 mov ax, 2
4 int 0x33;
5 }

Transcrierea unor instructiuni C/PASCAL in asamblare

IF cond THEN instr
Exemplu :
1 if (a==5) b=a; // a, b : integer ?

1 mov ax, a ?
2 cmp ax, 5
3 // ne intrebam daca !cond
4 jnz @skip_if
5 mov b, ax
6 @skip_if :

IF cond THEN instr1 ELSE instr2

Exemplu:
1 if (a==b) a-=b; else b-=a; ?

Transcrierea in asamblare :
1 mov ax, a ?
2 mov bx, b
3 // compara ax cu bx si seteaza flag-urile
4 cmp ax, bx
5 je @if_then
6 // if (ax == bx) sari la @if_then
7 sub b, ax
8 jmp @end_if :
9 @if_then :
10 sub a, bx
11 @end_if :

DO { inst } WHILE
Exemplu :
1 int i, a, n; ?
2 i = 0;
3 a = 0;
4 do
5 {
6 i++;
7 a+=i;
8 } while (i<=n);
Codul in asamblare :
 1 // cx = 0, instructiunea xor cx, cx este ?
2 // mai rapida decat mov cx, 0
3 xor cx, cx
4 xor ax, ax
5 mov bx, n
6 @while :
7 inc cx
8 add ax, cx
9 cmp cx, bx
10 jne @while
11 mov a, ax
12 mov I, cx
Sau folosind instructiunea loop (pornim invers) :
1 mov cx, n ?
2 @while:
3 add ax, cx
4 loop @while
In codul de mai sus (prima varianta) puteti observa cateva mici optimizari : retinerea variabilelor in registri (accesul la
registri este mult mai rapid decat la memorie), inlocuirea instructiunii { mov reg, 0 cu xor reg, reg. Varianta "xor" este
mai rapida (desi mov si xor "teoretic" au tot atatea ceasuri de procesor) deoarece instructiunea mov reg, 0 transcrisa
in cod masina este mai "lunga" (are cu 2-4 bytes mai mult decat xor reg, reg). Aceeasi regula se aplica si in cazul " or
reg, reg" in testarea daca valoarea unui registru este egala cu 0, intrucat instructiunea " or" modifica flagurile
procesorului (ZeroFlag). O alta optimizare este folosirea registrului ax pentru calcule (in majoritatea cazurilor
instructiunile care folosesc registrul ax sunt mai rapide).

Program demonstrativ
Exemplu de functie in realizata in C/Asamblare (compilator folosit BC++ 3.1):
1 // BSort.CPP ?
2 #include <stdio.h>
3 #include <conio.h>
4
5 int a[20], n;
6
7 void bsort()
8 {
9 asm {
10 mov di,seg a
11 mov es,di
12 mov di,offset a
13 // es:[di] inceputul vectorului
14 // es - adresa segment
15 // di - adresa offset
16 };
17
18 do_while_not_ok :
19 asm {
20 // ok = 1;
21 mov dx, 1
22 // cx = n;
23 mov cx, n
24 // cx = n-1
25
26 dec cx
27 // ax = a[0]
28 mov ax, es:[di]
29 // punem di pe stiva
30 push di
31 }
32 inner_for :
33 asm {
34 // bx = a[i-1]
35 mov bx, ax
36 // ne mutam pe noua pozitie in vector
37 add di, 2
38 // ax = a[i]
39 mov ax, es:[di]
40 // comparam ax cu bx (a[i-1] cu a[i])
41 cmp bx, ax
42 // if (a[i-1] <= a[i]) don't swap
 42 // if (a[i-1] <= a[i]) don't swap
43 jbe if_not
44 // interschimbam a[i-1] cu a[i]
45 xchg bx, ax
46 // le scriem in memorie
47 mov es:[di], ax
48 mov es:[di-2], bx
49 // ok = 0
50 xor dx, dx
51 }
52 if_not :
53 asm {
54 // cx--;
55 dec cx
56 jnz inner_for
57 // daca cx != 0 atunci continuam for-ul
58 pop di
59 // compara dx cu 0
60 // (mai rapid decat cmp dx, 0)
61 or dx, dx
62 // if (ok) executam inca odata while-ul
63 jz do_while_not_ok
64 }
65 }
66
67 void citire()
68 {
69 printf("Numarul de elemente : ");
70 scanf("%d", &n);
71 for (int i=0; i<n; i++)
72 {
73 printf("a[%d] = ", i);
74 scanf("%d", &a[i]);
75 }
76 }
77
78 void afis()
79 {
80 for (int i=0; i<n; i++)
81 printf("%d ", a[i]);
82 }
83
84 int main()
85 {
86 citire();
87 bsort();
88 afis();
89 return 0;
90 }
Varianta Pascal + Asm (compilata cu BP 7.0):
1 program b_sort; ?
2
3 const max_N = 1000;
4 n_tests = 100;
5
6 var N : Integer;
7 a, b : array [1..max_N] of Integer;
8
9 procedure citire;
10 var f : Text;
11 i : Integer;
12 begin
13 Assign(f, 'bsort.in'); Reset(f);
14 readln(f, N);
15 for i := 1 to N do
16 read(f, b[i]);
17 Close(f)
18 end;
19
20 procedure flip;
21 var i : Integer;
22 begin
23 for i:=1 to N do
24 a[i] := b[i];
25 end;
26
27 var p : pointer;
 27 var p : pointer;
28
29 procedure bsort; assembler;
30 asm
31 { les <=> es = seg(p), di = offset(p) }
32 les di, p
33 @do_while_not_ok :
34 mov dx, 1
35 mov cx, N
36 dec cx
37 mov ax, es:[di]
38 push di
39 @inner_for :
40 mov bx, ax
41 add di, 2
42 mov ax, es:[di]
43 cmp bx, ax
44 jbe @if_not
45 xchg bx, ax
46 mov es:[di], ax
47 mov es:[di-2], bx
48 xor dx, dx
49 @if_not :
50 dec cx
51 jnz @inner_for
52 pop di
53 or dx, dx
54 jz @do_while_not_ok
55 end;
56
57 procedure bsort2;
58 var ok : Boolean;
59 i, aux : Integer;
60 begin
61 repeat
62 ok := true;
63 for i := 1 to n-1 do
64 if (a[i] > a[i+1]) then
65 begin
66 aux := a[i];
67 a[i] := a[i+1];
68 a[i+1] := aux;
69 ok := false;
70 end;
71 until ok;
72 end;
73
74 var i : Integer;
75 starttick, endtick : LongInt;
76 time : Longint absolute $0000:$046C;
77
78 { timer pentru masurarea timpului }
79 const tickspersecond = 18.206;
80
81 procedure starttimer;
82 begin
83 starttick := time;
84 end;
85
86 function elapsedtime : real;
87 begin
88 endtick := time;
89 elapsedtime := (endtick - starttick)*
90 (1 / tickspersecond);
91 end;
92
93 begin
94 citire;
95 p := @a;
96 starttimer;
97 for i:=1 to n_tests do
98 begin
99 flip;
100 bsort;
101 end;
102 writeln(n_tests, ' rulari ale bsort in asamblare
103 au rulat in : ', elapsedtime : 6:3, ' secunde');
104 starttimer;
105 for i:=1 to n_tests do
106 begin
 106 begin
107 flip;
108 bsort2;
109 end;
110 writeln(n_tests, ' rulari ale bsort obisnuit
111 au rulat in : ',elapsedtime : 6:3, ' secunde');
112 end.
Output program pascal (pe pc-ul meu: Duron 750 Mhz):

100 rulari ale bsort in asamblare au rulat in : 1.263 secunde

100 rulari ale bsort obisnuit au rulat in : 4.614 secunde
De precizat este ca nu am optimizat programul aproape deloc (am transcris codul din pascal in asm). Cu optimizari
"hardcore" se pot obtine timpi mult mai buni. Diferenta dintre varianta asm si varianta high level language este mai
mica pe compilatoarele mai noi, cum ar fi GCC sau FreePascal deoarece acestea stiu genera un cod mai optimizat.
Totusi, nici un compilator nu poate bate creierul uman.

Linkuri
The Art of Assembly Language . O carte detaliata si foarte buna atat pentru incepatori cat si pentru avansati.
How to optimize for the Pentium processor . Un tutorial bun pentru optimizarea programelor in asamblare pentru
procesoarele din familia Pentium. Tutorialul este pentru avansati.
Assembly Tutorials . Mai multe tutoriale despre assembly language.

Doua cuvinte conclusive...

Acest articol trateaza "bazele" programarii in asamblare, dupa cum ii zice numele este doar o introducere. Pentru a sti
sa programezi in asm, trebuie invatate mult mai multe lucruri. Scopul articolului este de a starni interesul cititorilor si
de a le oferi o imagine asupra acestui limbaj. Cei ce doresc sa invete mai multe despre assembly language sunt invitati
sa citeasca cartile / tutorialele din sectiunea linkuri.

2004-2017 Asociatia infoarena

Cu ex ceptia cazurilor in care se specifica altfel, continutul site-ului infoarena
este publicat sub licenta Creative Com m ons Attribution-NonCom m ercial 2.5.