Introducere în SPICE.

Simularea de curent
continuu
Cuprinsul lecţiei: 1

 Ce este SPICE?
 Un exemplu
 Sintaxa SPICE
 Simulări de curent continuu
 Exerciții
 Concluzii și resurse

În această lecție sunt prezentate generalități privind SPICE, noțiunile elementare necesare
folosirii programului PSpice și aspecte legate de simularea circuitelor electrice funcționând în
curent continuu.

Ce este Spice?
SPICE (Simulation Program with Integrated Circuit Emphasis) este un simulator numeric de
circuite electrice și electronice de uz general, open-source (sursa lui este disponibilă oricărui
programator). SPICE este folosit în proiectarea circuitelor integrate, pentru a verifica
corectitudinea proiectării și pentru a prevedea comportarea reală a circuitelor. Pot fi folosite
diferite tipuri de analize precum analiza de curent continuu, analiza de regim tranzitoriu,
analiza în frecvență, analiza toleranțelor, analiza funcției de transfer, analiza de zgomot etc.
SPICE folosește pentru construirea sistemului de ecuații metoda modificată a potențialelor la
noduri adaptată analizei cerute. Plecând de la un fișier text netlist care descrie elementele de
circuit și conexiunile dintre ele, SPICE generează ecuațiile (sistem de ecuații diferențiale
algebrice neliniare) ce sunt rezolvate folosind metode de integrare implicită, metoda Newton
și tehnici cu matrici rare. SPICE poate simula cu precizie ridicată circuite care acoperă o
gamă variată de aplicații: de la surse în comutație până la celule de memorie, oscilatoare și
amplificatoare.

Prima versiune comercială a SPICE a fost ISPICE iar cele mai importante de-a lungul
timpului au fost HSPICE și PSPICE. În prezent există mai multe grupuri care continuă să
dezvolte SPICE precum ADICE (de la Analog Devices), LTspice (de la Linear Technology,
disponibil gratuit pentru public) și TINA (de la Texas Instruments). Aici am folosit pentru
simularea circuitelor versiunea gratuită PSpice Student 9.1.

Circuitele analizate cu SPICE pot conține rezistoare, condensatoare, bobine, bobine cuplate,
surse de tensiune și de curent independente, surse de tensiune și de curent dependente
(comandate), linii de transmisiune și cele mai uzuale dispozitive semiconductoare, diode,
tranzistoare bipolare – TB, tranzistoare cu efect de câmp cu grilă-joncțiune – TECJ,
tranzistoare cu efect de câmp metal-oxid-semiconductor (MOS) – TECMOS, tranzistoare cu
efect de câmp metal-semiconductor – TECMES etc.
Analiza de curent continuu (DC analysis) calculează PSF-ul (Punctul Static de Funcționare) în
condițiile în care condensatoarele sunt deconectate și bobinele scurtcircuitate. Sunt rezolvate
iterativ ecuațiile neliniare care descriu circuitul, neliniaritățile provenind în principal din
caracteristicile dispozitivelor semiconductoare.

Analiza de curent alternativ (analiza AC) calculează valoarea complexă a potențialelor

nodurilor unui circuit liniar în funcție de frecvența semnalului sinusoidal aplicat la intrare.
Pentru circuitele neliniare, cum ar fi de exemplu circuitele cu tranzistoare, acest tip de analiza
presupune realizarea condiției de semnal mic. Aceasta înseamna că amplitudinea tensiunii
sursei de excitație se presupune mică față de tensiunea termică (Vth=kT/q=25.8mV la 27ºC).
Numai în cazul respectării acestei condiții, circuitele neliniare pot fi înlocuite, pentru variații
în jurul punctului static de funcționare, prin echivalentul lor liniarizat.

În cazul analizei tranzitorii (transient analysis) se calculează pentru fiecare nod al circuitului
formele de undă în funcție de timp. Este o analiza de semnal mare, aceasta însemnând că
asupra amplitudinii semnalului de intrare nu se impune nicio restricție.

SPICE construiește și apoi rezolvă ecuațiile corespunzătoare circuitului analizat utilizând

metoda potențialelor la noduri în același fel în care un operator uman scrie mai intâi teoremele
Kirchhoff I și II pentru circuitul considerat și relațiile constitutive ale elementelor din laturi
iar apoi rezolvă sistemul de ecuatii rezultat. De aceea cea mai bună cale de a înțelege cum
funcționează SPICE este de a rezolva manual un circuit luat ca exemplu.

Un exemplu
Se consideră rețeaua rezistivă din figură:
Figura 1 Circuitul considerat (circuit în T podit)

Regimul de curent continuu va fi determinat inițial manual iar apoi folosind SPICE.

Se cer potențialele nodurilor circuitului rezistiv in T podit din Figura 1 și să se determine

curentul furnizat de sursa de polarizare Vpolarizare. Valorile sunt: Vpolarizare=12V, R1=10Ω,
R2=10Ω, R3=5Ω, R4=5Ω. Nodurile sunt numerotate 0,1,2,3.

Soluție: Potențialul nodului 1 este egal cu Vpolarizare , adică 12V. Potențialele nodurilor 2 și 3
se determină prin rezolvarea sistemului care rezultă prin scrierea ecuațiilor la noduri:

Nodul 2: -G1V1+(G1+G2+G3)V2-G3V3=0 (ecuația 1)

Nodul 3: -G4V1-G3V2+(G3+G4)V3=0 (ecuația 2)

G1, G2, G3 si G4 fiind conductanțele corespunzătoare rezistoarelor R1, R2, R3, R4: G1 = G2 =
0.1 S și G3 = G4= 0.2 S. Acest sistem de două ecuații cu două necunoscute V2 , V3 :

0.4V2-0.2V3 = 1.2
 -0.2V2+0.4V3 = 2.4

se rezolvă imediat. Soluția este:

V2 = 8V

V3 = 10V

Curentul prin sursa de polarizare este egal cu curentul IR2 :

Ivpolarizare = IR2 = G2V2 =0.8 A

În SPICE ecuațiile 1 și 2 sunt formulate pornind de la graful care descrie topologia circuitului
și sunt apoi rezolvate prin utilizarea eliminării Gaussiene. Rezultatele obținute în exemplul de
față prin analiza manuală a circuitului sunt comparate cu acelea obținute folosind SPICE.

Sintaxa SPICE
Am folosit PSpice, versiunea pentru PC a programului SPICE. Versiunea Student gratuită a
PSpice poate fi descărcată de aici.

Versiunea online a simulatorului SPICE poate fi găsită la adresa: www.partsim.com.

O altă variantă SPICE pentru PC este programul LTSpice ce poate fi descărcat de la adresa:
www.linear.com.

Revenind la exemplu, schema circuitului trebuie descrisă într-un format care să poată fi
ințeles de către SPICE. În această etapă vom examina tipurile de informații conținute de
fișierul de intrare netlist. Schema circuitului poate fi descrisă și direct folosind un editor grafic
- Schematics, caz în care fișierul netlist este generat automat. Fișierul netlist poate fi editat cu
orice editor de text.

Limbajul de intrare SPICE constă dintr-o succesiune de declarații. O linie care continuă linia
precedentă trebuie să înceapă cu un + în prima coloana. O declarație conține un număr de
câmpuri separate prin caractere de delimitare care pot fi un spațiu, o virgula, un semn egal (=)
sau o paranteză la dreapta sau la stânga; spațiile suplimentare sunt ignorate. Programul nu
face diferența între majuscule și minuscule (este case insensitive).

În cele ce urmează, elementele sintactice ale limbajului SPICE se vor introduce în mod
natural prin crearea fișierului de intrare SPICE pentru circuitul în T podit din Figura 1.

<="" p="">

Unele linii au în prima coloană un asterisc; acestea sunt declarații comentariu (comment
statements) care pot fi folosite pentru comentarii legate de descrierea circuitului și de cererile
de analiza.

Specificația SPICE este orientată spre componenta de circuit. Ca urmare, pentru a descrie
circuitul din Figura 1, este necesar ca informațiile conținute în figura (numele, conectivitatea
si valoarea elementului) să fie transferate unui fișier text, prezentat mai jos. Descrierea
circuitului constă din declarațiile din liniile 3-7; fiecare element poate fi identificat cu ușurinta
în figură. Celelalte linii din fișierul de intrare SPICE sunt titlul, care specifică circuitul drept
CIRCUIT T PODIT, două linii de comentarii care au un asterisc în prima coloană și linia
.END care întotdeauna trebuie să încheie fișierul netlist.

Alt tip de declarație care trebuie să apară într-un fișier de intrare SPICE este declarația de
control (control statement). Declarația de control conține un punct în prima coloană și
specifică tipul de analiză care trebuie realizat și variabilele de ieșire care trebuie memorate.
Pentru verificarea calculului manual al punctului static de funcționare, programului i se cere,
prin introducerea liniei .OP să facă analiza de curent continuu a circuitului (calculul punctului
static de funcționare - Operating Point, adică valorile potențialelor nodurilor).

CIRCUIT T PODIT
*
VPOLARIZARE 1 0 12
R1 1 2 10
R2 2 0 10
R3 2 3 5
R4 1 3 5
*
.OP
.END

Această descriere a circuitului este salvată în fișierul circuitT.cir care este utilizat ca fișier de
intrare pentru SPICE. Descrierea circuitului este citita de catre SPICE si compilată într-o
reprezentare internă. Ecuațiile la noduri, identice cu ecuațiile 1 și 2 sunt stabilite intern în
SPICE și rezolvate ca un sistem de ecuații liniare.

SPICE face distincție între câmpurile alfanumerice (name fields) și câmpurile numerice
(number fields). Un câmp alfanumeric, de exemplu Q1, RB sau , QMOD trebuie să înceapă cu
o litera (A-Z) urmată de alte litere sau numere.

Un câmp numeric poate conține un întreg, de exemplu 5 sau -123, un număr în virgulă
mobilă, de exemplu 3.14159, un număr în virgulă mobilă scris în notație inginerească, de
exemplu 1E-16 sau 2.65E5 sau fie un întreg, fie un numar în virgulă mobilă urmat de unul de
factorii de scala recunoscuti de SPICE (a se vedea tabelul următor).

Valoare Simbol
10^(-15) F
10^(-12) P
10^(-9) N
10^(-6) U
10^(-3) M
25.4*10^(-6) MIL
10^(3) K
10^(6) MEG
10^(9) G
10^(12) T
Într-un câmp numeric, o literă care urmează imediat fie după un factor de scala, fie după un
număr și nu este factor de scală este ignorată. Deci 10, 10V, 10VOLTS și 10HZ reprezintă
același număr, iar M, MA, MSEC reprezinta același factor de scala 10^(-3). Se pot adăuga
unitățile de măsură la câmpul numeric, de exemplu 10V, 1PF sau 10UM. Toate aceste
specificații sunt valabile numai atât timp cât unitatea de masura nu se confundă cu factorul de
scala: de exemplu 1F în SPICE înseamnă 10E-15 si nu 1 Farad. Alta greșeală tipică este dată
de confuzia între M, MEG și MIL: 20MHZ nu inseamna 20 de MegaHertz ci 20 de miliHertz
iar 0.1MIL nu inseamna 0.1 milimetri ci 25.4 micrometri.

Descrierea circuitului se compune dintr-un număr de declarații de element ce conțin numele

elementului de circuit, nodurile din circuit la care este conectat elementul de circuit și valorile
parametrilor care determină caracteristicile electrice ale elementului de circuit. Formatul
general al unei declarații de element este:

Un_nume nod1 nod2 <nod3...> <MODEL_nume> <valoare1...>

Primul câmp conține întotdeauna numele elementului. Numele elementului trebuie să înceapă
cu o literă care definește tipul elementului, de exemplu R pentru rezistoare, Q pentru
tranzistoare bipolare si V pentru surse de tensiune. Cu exceptia primei litere, restul numelui
elementului poate conține atât caractere cât și numere.

Câmpurile următoare nod1, nod2, <nod3...> reprezintă numerele nodurilor la care este
conectat elementul. Pentru specificarea nodurilor este permisă și folosirea numelor. De
remarcat că numerotarea nodurilor începe cu 0, nodul 0 fiind nodul de referință (potențialul
V0=0). Deasemenea începutul și sfârșitul unui element reprezinta un nod, deci în SPICE vor fi
mai multe noduri decât la rezolvarea analitică. Un nod este intersecția a două sau a mai multor
laturi.

În funcție de tipul lor, elementele de circuit sunt caracterizate printr-o valoare valoare1 sau un
model MODEL_nume, urmate de una sau de mai multe valori opționale. Pentru fiecare
MODEL_nume la care se face referire, specificația de circuit trebuie să conțină o declarație
.MODEL. Declarația .MODEL aparține unei alte categorii de declarații, declarațiilor globale
(global statements).

În continuare sunt date câteva exemple de declarații de elemente:

 Rezistorul liniar: R_nume nod+ nod- valoare

 Sursa independenta de tensiune: V_nume nod- nod+ [DC] valoare
 Sursa independenta de curent: I_nume nod+ nod- [DC] valoare

Figura 2 Simbolurile rezistorului, al sursei de tensiune si de curent și notarea nodurilor.

Un alt tip de declarație folosită în fișierul de intrare SPICE este declarația (declarațiile) de
control. Declarațiile de control specifică tipurile de analize pe care trebuie să le realizeze
SPICE și totodata definește stările inițiale. Toate declarațiile de control încep cu un punct în
prima coloană.

În exemplul anterior, calcularea punctului static de funcționare este cerută prin linia .OP și are
ca rezultat calcularea potențialelor nodurilor.

În rezumat, orice fișier de intrare SPICE are următoarea structură generală:

Declaratia de titlu
*Declaratii comentariu
Declaratii de element
Declaratii globale
Declaratii de control
.END

Simulări de curent continuu

Să scriem datele corespunzătoare circuitului în T podit de mai sus.

Urmați pașii de mai jos pentru introducerea componentelor schemei (pentru a trece de la un
pas la altul, fie apăsați pe grila de jos, fie în partea stângă sau dreaptă a fiecărei imagini):

Start -> All Programs -> PSpice Student -> PSpice AD Student

Se deschide această fereastră

Selectați editorul de text

Nodurile sunt numerotate ca în schemă

Să scriem linia de titlu

Să scriem o linie de comentariu

Sursa de tensiune se află între nodurile 1 și 0 și are valoarea de 12V

R1 se află între nodurile 1 și 2 și are valoarea de 10Ω

Se introduc și restul rezistențelor

Se scrie comanda de aflare a potențialelor și fișierul se termină cu .END

Se salvează fișierul cu numele circuitT.cir pe Desktop

Se redeschide fișierul pentru a se activa

Simulați circuitul

Vedeți fișierul de ieșire
 
Comparați cu potențialele obținute pe hârtie (vedeți mai jos)

 1
 2
 3
 4
 5
 6
 7
 8
 9
 10
 11
 12
 13
 14
 15

Se obține fișierul de mai jos. Se poate verifica identitatea dintre rezultatele obținute în urma
simularii și rezultatele obținute prin analiza manuală (potențialele nodurilor).
**** 03/21/09 15:18:08 *********** Evaluation PSpice (Nov 1999)
**************

CIRCUIT T PODIT

**** CIRCUIT DESCRIPTION

***************************************************************************
***

*
VPOLARIZARE 1 0 12
R1 1 2 10
R2 2 0 10
R3 2 3 5
R4 1 3 5
*
.OP
.END

**** 03/21/09 15:18:08 *********** Evaluation PSpice (Nov 1999)

**************

CIRCUIT T PODIT

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG C

***************************************************************************
***

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 12.0000 ( 2) 8.0000 ( 3) 10.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

VPOLARIZARE -8.000E-01

TOTAL POWER DISSIPATION 9.60E+00 WATTS

**** 03/21/09 15:18:08 *********** Evaluation PSpice (Nov 1999)

**************

CIRCUIT T PODIT
 **** OPERATING POINT INFORMATION TEMPERATURE = 27.000 DEG C

***************************************************************************
***

JOB CONCLUDED

TOTAL JOB TIME .03

Să simulăm acum un alt circuit de curent continuu. Schema lui împreună cu notarea nodurilor
este dată în Figura 4.

Figura 4 Circuitul de simulat

Pentru a putea afișa alte valori în afară de potențialele nodurilor, trebuie să folosim comanda
.PRINT. Ea are multe utilizări dar ne vom concentra aici asupra tipăririi tensiunilor și a
curenților DC. Comanda .PRINT poate fi repetată în analiză de atâtea ori cât este necesar. Pot
fi listate oricâte elemente dorite.

Totuși trebuie avut în vedere că instrucțiunea .PRINT a fost proiectată pentru a lucra cu o
analiza DC sau AC. Aceasta este o metodă de a varia un parametru pe un domeniu de valori
astfel încât să avem toate cazurile rezolvate imediat. Adesea nu dorim să facem o analiză pe
mai multe valori ale unui parametru. Putem constrânge analiza stabilind domeniul astfel încât
să ruleze pe o singură valoare. De obicei o analiza DC este realizată modificând valorile unei
surse. Iată care este sintaxa unei analize DC folosind tipul liniar implicit al domeniului:

.DC variabila_de_analiza valoare_de_start valoare_finala pas

Pentru exemplul nostru alegem sursa de tensiune și stabilim domeniul variabilei la o singură
valoare.

.DC V1 90 90 1

Deoarece valoarea inițiala este egală cu valoarea finală, analiza va fi realizată pentru un singur
caz, adică pentru V1=90V. De remarcat că motivul pentru care includem instructiunea .DC
este de a activa comanda .PRINT. Comanda .PRINT nu va funcționa decat dacă este activă o
comanda .DC sau .AC.

Atunci când se folosește instrucțiunea .DC, aceasta suprapune orice valoare a sursei
corespunzătoare din lista de descriere a circuitului.

În plus față de afișarea tensiunilor nodurilor la care se tasteaza "V" urmat de numărul nodului
între paranteze, poate fi afișata și tensiunea între orice pereche de noduri. V(m,n) afiseaza
tensiunea de la nodul m la nodul n. De exemplu:

.PRINT DC V(0,3)

Pentru a afișa curenți, tastați litera "I" cu numele elementului între paranteze. Curentul afișat
este cel care parcurge elementul de la nodul din stânga la cel din dreapta din fișierul .CIR.
Dacă se dorește schimbarea semnului curentului afișat de exemplu pentru un rezistor, trebuie
schimbate între ele cele 2 noduri ale rezistorului.

Urmați pașii de mai jos:


Creați un fișier nou

Fișierul este următorul

Salvați fișierul cu numele cc1.cir și apoi deschideți-l pentru a se activa

Simulați fișierul
 
Vedeți fișierul de ieșire

 1
 2
 3
 4
 5

Se obține fișierul de mai jos. Se poate verifica identitatea dintre rezultatele obținute în urma
simularii și rezultatele obținute prin analiza manuală (potențialele nodurilor).

**** 03/05/15 13:29:44 *********** Evaluation PSpice (Nov 1999)

**************

simulare 2

**** CIRCUIT DESCRIPTION

***************************************************************************
***
V1 2 0 90
V2 0 6 20
V3 4 5 20
I1 3 1 5
R1 1 6 20
R2 3 2 5
R3 1 4 10
R4 3 5 2
R5 5 0 5
.dc V1 90 90 1
.print dc I(R1) I(R2) I(R3) I(R4) I(R5) V(I1)
.end

**** 03/05/15 13:29:44 *********** Evaluation PSpice (Nov 1999)

**************

simulare 2

**** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG C

***************************************************************************
***

V1 I(R1) I(R2) I(R3) I(R4) I(R5)

9.000E+01 4.000E+00 -1.000E+01 1.000E+00 5.000E+00 6.000E+00

**** 03/05/15 13:29:44 *********** Evaluation PSpice (Nov 1999)

**************

simulare 2

**** DC TRANSFER CURVES TEMPERATURE = 27.000 DEG C

***************************************************************************
***

V1 V(I1)

9.000E+01 -2.000E+01

JOB CONCLUDED

TOTAL JOB TIME .02

Exerciții
Aflați potențialele nodurilor și curenții prin laturi pentru următoarele circuite analitic pe hârtie
si apoi folosind PSpice:

Figura 5 Exercițiul 1
Figura 6 Exercițiul 2
Figura 7 Exercițiul 3

Concluzii și resurse suplimentare

În această lecție am vazut ce este SPICE, care este sintaxa SPICE și am investigat mai multe
circuite folosind analiza de curent continuu.

În lecția următoare vom studia circuite de curent continuu ce conțin surse comandate.

Ca referințe puteți consulta cărțile citate si deasemenea ar fi util să încercați să folosiți și

simulatorul online www.partsim.com și o alta variantă pentru PC a Spice, LTSpice.
Deasemenea puteți încerca să întroduceți direct schema circuitului de analizat folosind
editorul grafic Schematics.
Circuite cu surse comandate în curent
continuu
Cuprinsul lecţiei: 2

 Despre sursele comandate

 Sursa de tensiune comandată în tensiune
 Sursa de tensiune comandată în curent
 Sursa de curent comandată în tensiune
 Sursa de curent comandată în curent
 Probleme
 Concluzii

În această lecție este continuată analiza de curent continuu pentru circuitele ce conțin surse
dependende (comandate) liniar.

Despre sursele comandate

Cele patru tipuri de surse comandate generează multipli ai tensiunii sau ai curentului de
comandă. Se pot însă modela și surse comandate care să fie funcții neliniare mai complicate
de mai multe tensiuni și/sau curenți de comandă. În continuare ne vom concentra însă numai
asupra surselor de bază comandate liniar.

Pentru identificarea laturilor de comandă ale surselor comandate în curent, se introduc surse
ideale independente de tensiune cu valorile t.e.m. egale cu 0. Această tensiune se pune pe
latura curentului de comandă, în sens invers curentului de comanda. Această sursă reprezintă
un element în plus, deci va determina apariția unui nod suplimentar. Dacă totuși se intampla
ca în latura de comandă să avem o sursă de tensiune independentă, o putem folosi în locul
sursei suplimentare.

Circuitele cu surse comandate nu respectă teorema reciprocității și de aceea se numesc și

nereciproce.

Teorema reciprocității

Curentul electric produs într-o latura j a unei rețele electrice liniare de o sursă situată într-o
latură k, fără să mai existe alte surse în rețea, este egal cu curentul pe care l-ar produce în
latura k aceeași sursă, situată în latura j, rezistențele laturilor ramânând neschimbate.

Sursa de tensiune comandată în tensiune

Figura 1 Sursa de tensiune comandată în tensiune (latura comandată în stânga și latura de
comandă în dreapta)

Ecuația de funcționare a acestei surse este: Ei=AUj, unde A este factorul de amplificare în
tensiune (adimensional).

Iata cum se declara in Spice o astfel de sursa:

E_nume N- N+ NC+ NC- valoare

Prima literă din descrierea sursei de tensiune comandată în tensiune este "E". Aceasta este
litera care trebuie să apară în prima coloană a fișierului *.CIR unde se descrie componenta.

N-, N+ sunt nodurile între care este conectată sursa de tensiune (a laturii comandate).

NC+, NC- sunt nodurile de conexiune ale tensiunii de comandă (latura de comandă).

În continuare sunt date câteva exemple de declarații de astfel de surse:

E1 12 14 21 13 14.0; factorul de amplificare este 14

E2 5 3 14 7 20
E2 5 3 7 14 -20; acelasi lucru ca mai sus
E2 3 5 14 7 -20; acelasi lucru ca mai sus
E2 3 5 7 14 20; acelasi lucru ca mai sus

Sursa de tensiune comandată în curent

Figura 2 Sursa de tensiune comandată în curent (latura comandată în stânga și latura de
comandă în dreapta)

Ecuația de funcționare a acestei surse este: Ei=RtIj, unde Rt este rezistența de transfer.

Sursa de tensiune comandată în curent generează o tensiune proporțională cu curentul Ij dintr-

o ramură diferită a rețelei. Rezistența de transfer Rt masurată în Ω este multiplicată cu Ij
măsurat în amperi pentru a genera tensiunea sursei comandate măsurată în volți. Ramura de
comandă nu se poate specifica prin nodurile sale. De aceea, asa cum am menționat și in
observația din introducere, trebuie să introducem o sursă de tensiune independentă de valoare
0, în serie cu ramura ce conține curentul de comandă astfel încât curentul de comandă să fie în
sens invers față de sursă. Daca totuși se intâmplă ca în latura de comandă să avem o sursă de
tensiune independentă, o putem folosi în locul sursei suplimentare (dacă este necesar, se poate
folosi un semn minus pentru a obține polaritatea corectă).

Iată cum se declară în Spice o astfel de sursă:

H_nume N- N+ V_comanda valoare

Prima literă din descrierea sursei de tensiune comandată în tensiune este "H". Aceasta este
litera care trebuie să apară în prima coloană a fișierului *.CIR unde se descrie componenta.

N-, N+ sunt nodurile între care este conectată sursa de tensiune (a laturii comandate).

V_comanda este sursa ideală de tensiune care identifică latura de comandă, al cărei curent
comandă sursa de tensiune H_nume.

valoare - este valoarea rezistenței de transfer Rt.

În continuare sunt date câteva exemple de declarații de astfel de surse:

Hvx 10 6 Vhx 25
Vhx 70 56 0V; comanda sursa Hvx
Hab 5 0 V20 125
V20 7 2 0V; comanda sursa Hab
HAL 10 6 V_3 10
V_3 3 5 20; sursa reala (diferita de 0) ce comanda sursa HAL

Sursa de curent comandată în tensiune

Figura 3 Sursa de curent comandată în tensiune (latura comandată în stânga și latura de
comandă în dreapta)

Ecuația de funcționare a acestei surse este: Igi=GtUj, unde Gt este conductanța de transfer.

Iată cum se declară în Spice o astfel de sursă:

G_nume N+ N- NC+ NC- valoare

Prima literă din descrierea sursei de tensiune comandată în tensiune este "G". Aceasta este
litera care trebuie să apară în prima coloană a fișierului *.CIR unde se descrie componenta.

N+, N- sunt nodurile între care este conectată sursa de curent (a laturii comandate).

NC+, NC- sunt nodurile tensiunii de comanda.

valoare - este valoarea conductanței de transfer Gt.

În continuare sunt date câteva exemple de declarații de astfel de surse:

Glab 23 17 8 3 2.5
G1 12 9 1 0 4E-2
Grad 19 40 6 99 0.65
Grad 19 40 99 6 -0.65; acelasi lucru ca mai sus
Grad 40 19 99 6 0.65; acelasi lucru ca mai sus

Sursa de curent comandată în curent

Figura 4 Sursa de curent comandată în curent (latura comandată în stânga și latura de
comandă în dreapta)

Ecuația de funcționare a acestei surse este: Igi=BIj, unde B este factorul de amplificare în
curent (adimensional).

Ramura de comandă nu se poate specifica prin nodurile sale. De aceea, așa cum am menționat
și în observația din introducere, trebuie să introducem o sursă de tensiune independentă de
valoare 0, în serie cu ramura ce conține curentul de comandă astfel încât curentul de comandă
să fie în sens invers față de sursă. Daca totuși se intâmplă ca în latura de comandă să avem o
sursă de tensiune independentă, o putem folosi în locul sursei suplimentare (dacă este necesar,
se poate folosi un semn minus pentru a obține polaritatea corectă).

Iată cum se declară în Spice o astfel de sursă:

F_nume N+ N- V_comanda valoare

Prima literă din descrierea sursei de tensiune comandată în tensiune este "F". Aceasta este
litera care trebuie să apară în prima coloană a fișierului *.CIR unde se descrie componenta.

N+, N- sunt nodurile între care este conectată sursa de curent (a laturii comandate).

V_comanda este sursa ideală de tensiune care identifică latura de comandă, al cărei curent
comandă sursa de curent F_nume.

valoare - este valoarea factorului de amplificare în curent B.

În continuare sunt date câteva exemple de declarații de astfel de surse:

Ftrn 81 19 Vctl 50.0

Vctl 23 12 0; controleaza Ftrn
Fcrt 63 48 Vx 20.0
Vx 33 71 0; controleaza Fcrt
F3 2 0 15.0
V1 3 1 0; controleaza F3

Probleme cu surse comandate

Să se afle folosind PSpice curenții prin laturile următoarelor circuite (se vor folosi comenzile
.DC și .PRINT DC ca în lecția anterioară):
a). Se dau: R1=R5=R21=2Ω, R2=1Ω, R3=4Ω, J4=4A, E1=12V, E3=4V, E2=R21*I1

Figura 5 Exercițiul 1

b). Se dau: R1=5Ω, R3=4Ω, R4=3Ω, R5=2Ω, E1=78V, J2=6A, E3=0.5*Ug2, J5=0.5*I4
Figura 6 Exercițiul 2

c). Se dau: R1=R2=R3=R4=2Ω, E1=12V, E2=6V, J5=1*U1

Figura 7 Exercițiul 3

Concluzii și resurse suplimentare

În această lecție am continuat analiza de curent continuu introducând patru noi tipuri de
dispozitive: sursele comandate. Lucrurile se complică puțin atunci când avem surse
comandate în curent deoarece trebuie introdusă o sursă de tensiune nulă în latura de comandă.
În rest, declarațiile elementelor și declarațiile de control sunt aceleași cu cele descrise în lecția
anterioară.

Sursele comandate au aplicații mult mai numeroase în modelarea dispozitivelor neliniare

semiconductoare și în multe alte tipuri de analize.

În laboratorul următor ne vom ocupa de analiza în domeniul frecvență cu care pot fi rezolvate
circuite de curent alternativ și de diverse tipuri de filtre.
Analiza de curent alternativ. Filtre
Cuprinsul lecţiei: 3

 Ce este analiza AC?

 Surse în c.a.
 Folosirea comenzii .PRINT AC
 Exemple pentru frecvență unică
 Exemple pentru domenii de frecvențe
 Filtre pasive
 Probleme
 Concluzii

În această lecție vom analiza circuite în regim permanent sinusoidal (curent alternativ) - deci
cu frecvență fixă dar și circuite ce iau în calcul un domeniu de frecvențe, de exemplu filtrele
analogice. După o prezentare teoretică a analizei AC din Spice, sunt prezentate câteva
exemple de circuite la care se folosește această analiză. Sunt deasemenea propuse probleme
pe care să le rezolvați.

Ce este analiza AC?

Spice poate fi folosit și pentru analiza de curent alternativ - AC (fie că este vorba de o singură
frecvență, fie că este vorba de un domeniu de frecvențe). Pentru obținerea rezultatelor în
cadrul analizei de curent continuu am avut nevoie de tandemul comezilor ".DC" și ".PRINT
DC". Acum avem o situație similară folosind comenzile ".AC" și ".PRINT AC".

Spice calculează în modul de simulare de curent alternativ răspunsul în frecvență al

circuitelor liniare și al celor echivalente de semnal mic. Spice folosește pentru analiza de c.a.
metoda nodală modificată în complex, astfel încât operează cu fazori.

Surse în curent alternativ

Până acum toate sursele de tensiune și de curent folosite erau în curent continuu. Sintaxa
surselor AC este asemănătoare.

Original în Spice avem convenția ca o sursă AC să fie o cosinusoidă cu o fază inițială

precizată: x(t)=Xmaxcos(ωt+α). Informațiile ce trebuiesc furnizate sunt: numele sursei care
trebuie să înceapă cu V sau I, nodurile între care este conectată, valoarea maximă (Xmax) și
faza sa inițială (α). Separat, frecvența tuturor surselor din circuit este definită printr-o
comandă ".AC". Dăm câteva exemple de definiții de surse:

*nume lista_nodurilor tip valoare fază(grade)

V1ac 1 0 AC 230V 45
Vba 2 3 AC 240; fază inițială 0 grade
I3y 3 4 AC 10.0A -45; fază inițială -45 grade
Is1 1 9 AC 35mA; 35 miliamperi la 0 grade
La seminar folosim forma sinusoidală: x(t)=Xef2sin(ωt+α1). Așa cum am spus anterior, în
Spice, ca și în sistemul american, se folosesc cosinusoide. Pentru echivalență se pot folosi
formulele cunoscute: Xmax=Xef2 și α=α1−π2. Oricum acest lucru nu este obligatoriu
deoarece variabila timp nu intervine în analiza de curent alternativ și se poate folosi pentru
variabila α chiar valoarea variabilei α1 atunci când alegem convenția corespunzătoare formei
sinusoidale și nu cosinusoidale (vom vedea diferențele la analiza tranzitorie - în domeniul
timp). Pentru concordanța cu seminarul, această convenție (sinusoidală) o vom folosi în
continuare.

O altă observație ar fi că este obligatorie specificarea tipului AC la definirea surselor deoarece

cel implicit este DC. Faza este măsurată în grade. Dacă nu se precizează faza, aceasta se
presupune 0. În exemplele anterioare V și A (ca unitați de măsură) sunt opționale după
valorile tensiunii și ale curentului.

Alte elemente de circuit

Rezistorul se declară la fel ca în curent continuu:

R_nume N- N+ valoare_in_Ohm

Condensatorul liniar se declară în Spice astfel:

C_nume N+ N- valoare_in_Farad

Bobina liniară se declară în Spice astfel:

L_nume N- N+ valoare_in_Henri

Folosirea comenzii .PRINT AC

Pentru a putea folosi comanda .PRINT AC, trebuie activată comanda .AC. Comanda .AC este
folosită pentru a parcurge un domeniu de frecvențe pentru un circuit dat. Aceasta corespunde
găsirii răspunsului în frecvență. Există 3 tipuri de parcurgere a domeniului frecvență: LIN,
DEC și OCT. Urmează câteva exemple de comenzi .AC:

.AC LIN 1 50Hz 50Hz

.AC LIN 11 150 250; o baleiere liniară a domeniului
.AC DEC 20 10Hz 100kHz; o baleiere pe decade a domeniului

Prima comandă realizează o analiză numai pentru frecvența de 50Hz (am ales domeniul
liniar). Adăugarea unităților Hz după valoare este opțională. Cea de-a două comandă parcurge
domeniul format din frecventele 150Hz, 160Hz, 170Hz, 180Hz, 190Hz, 200Hz, 210Hz,
220Hz, 230Hz, 240Hz si 250Hz. Cea de-a treia comanda parcurge logaritmic domeniul
folosind 20 de puncte pe decadă pe un domeniu de 4 decade (10Hz-100Hz, 100Hz-1kHz,
1kHz-10kHz și 10kHz-100kHz).

Să analizăm acum comanda .PRINT AC. Afișarea componentelor fazoriale (numere

complexe) necesită anumite opțiuni. Există 4 expresii necesare pentru aceasta: modul, fază,
parte reală și parte imaginară. Pot fi afișate tensiuni și curenți. De exemplu, pentru a afișa
modulul unei tensiuni dintre nodurile 2 și 3, vom specifica VM(2,3), sau simplu V(2,3). Faza
în grade pentru aceeași tensiune va fi VP(2,3). Dacă dorim modulul curentului prin rezistorul
Rsarcina, se specifică IM(Rsarcina). Partea reală a tensiunii la nodul 7 va fi VR(7) iar partea
sa imaginară, VI(7). Ca și în cazul comenzii .PRINT DC, nu există un număr limită de câte ori
poate fi folosită. Urmează câteva exemple:

.PRINT AC VM(30,9) VP(30,9); modulul și faza tensiunii

.PRINT AC IR(Rs) II(Rs); părțile reală și imaginară ale curentului prin Rs
.PRINT AC VM(13) VP(13) VR(13) VI(13); toate informațiile la nodul 13

Pentru afișarea unor grafice în funcție de frecvență, se folosește comanda .PROBE. Pentru a
vizualiza diferite variații, folosim din meniu Trace->Add Trace de unde putem alege fie
mărimea respectiva, fie diferite funcții ale mărimii. (De exemplu pentru variația fazelor, se
alege funcția P(), pentru variația părții imaginare, se alege functia IMG(), pentru variația părții
reale, se alege funcția R(). )

Exemple pentru frecvență unică

Ex1.1: Circuit R-L serie

În figura 1 este prezentat un circuit format dintr-o rezistență R1=10Ω și o bobină L1=10mH,
legate în serie. Combinația poate reprezenta, de exemplu, cazul unei bobine reale. Vom
calcula curentul prin circuit pentru un semnal sinusoidal aplicat la intrare Vin, de amplitudine
1V și frecvență f=100Hz.

Figura 1 Circuit R-L serie

Se folosește următorul program:

Circuit R-L serie

Vin 1 0 AC 1
R1 1 2 10
L1 2 0 10m
.AC LIN 1 100 100
.PRINT AC I(R1) IP(R1) IR(R1) II(R1)
.END

În urma rulării programului se obține fișierul de ieșire:

**** 04/01/15 17:10:46 *********** Evaluation PSpice (Nov 1999)

**************

Circuit R-L serie

**** CIRCUIT DESCRIPTION

***************************************************************************
***

Vin 1 0 AC 1
R1 1 2 10
L1 2 0 10m
.AC LIN 1 100 100
.PRINT AC I(R1) IP(R1) IR(R1) II(R1)
.END

**** 04/01/15 17:10:46 *********** Evaluation PSpice (Nov 1999)

**************

Circuit R-L serie

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG C

***************************************************************************
***

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 0.0000 ( 2) 0.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

Vin 0.000E+00

TOTAL POWER DISSIPATION 0.00E+00 WATTS

**** 04/01/15 17:10:46 *********** Evaluation PSpice (Nov 1999)

**************
 Circuit R-L serie

**** AC ANALYSIS TEMPERATURE = 27.000 DEG C

***************************************************************************
***

FREQ I(R1) IP(R1) IR(R1) II(R1)

1.000E+02 8.467E-02 -3.214E+01 7.170E-02 -4.505E-02

JOB CONCLUDED

TOTAL JOB TIME .03

Se observă următoarele:

 Calculul punctului de polarizare are ca rezultat valori nule pentru toate potențialele
nodurilor deoarece în circuit nu avem surse de curent continuu.
 Curentul prin sursă și puterea debitată de ea sunt nule din aceleași cauze.
 Frecvența de analiză este de 100Hz, amplitudinea curentului prin circuit este de 84mA
și este defazat în urma tensiunii cu 32°.

Aceste rezultate permit calcularea următoarelor mărimi:

 Impedanța circuitului Z=VinI(R1)=11.9*exp(j*32°)

 Puterile activă, reactivă și aparentă:

P=U*I*cosφ=1V*0.084A*cos32°=0.0712W
Q=U*I*sinφ=1V*0.084A*sin32°=0.0445VAR
S=U*I=1V*0.084A=0.084VA

Ex1.2: Circuit R-C serie

Circuitul R-C serie cu valorile R1=10Ω și C1=100µF este prezentat în figura 2. Vom analiza
circuitul la frecvență f=318Hz.
Figura 2 Circuit R-C serie
Circuit R-C serie
Vin 1 0 AC 1
R1 1 2 10
C1 2 0 100u
.AC LIN 1 318 318
.PRINT AC I(R1) IP(R1) V(R1) V(C1)
.END

Folosind fișierul de ieșire arătați că Vin=V2(R1)+V2(C1)

Ex1.3: Circuit R-L-C serie

Circuitul R-L-C serie este prezentat în figura 3. Comportarea sa în regim sinusoidal depinde
de frecvență și putem distinge tre situații.
Figura 3 Circuit R-L-C serie

a). Rezonanța tensiunilor (comportare rezistivă)

Aceasta are loc atunci când UL=UC deci XL=XC. Aceasta se întâmplă la frecvența:

ω=ω0=1LC

La această frecvență circuitul are un caracter pur rezistiv, impedanța sa fiind minimă:

|Z|=|Z|min=R2+(XL−XC)2=R

iar curentul prin circuit are valoarea maximă egală cu:

Imax=UZmin=UR

b). Comportare capacitivă

Pentru ω=ω1<ω0, avem XC>XL și deci U_C>U_L iar circuitul se va comporta ca un grup
R−Cechivalent și va determina un defazaj al curentului înaintea tensiunii la borne.

c). Comportare inductivă

Pentru ω=ω2>ω0, avem XL>XC și deci U_L>U_C iar circuitul se va comporta ca un grup
serie R−Lechivalent și va determina un defazaj al curentului în urma tensiunii la borne.

Considerând valorile R=100Ω, L=25.33mH și C=1μF, frecvența de rezonanță are aproximativ

valoarea f0=1000Hz. Rulați următorul fișier Spice:
Circuit R-L-C serie
Iin 0 1 AC 1
R 1 2 100
L 2 3 25.33m
C 3 0 1u
RC 3 0 1meg
.AC LIN 1 1000 1000
.PRINT AC V(1) VP(1)
.PRINT AC V(R) VP(R) V(L) VP(L) V(C) VP(C)
.END

Linia de program RC 3 0 1meg a fost introdusă deoarece sursa de curent are rezistență internă
infinită și astfel nodurile 1, 2 și 3 nu ar avea o cale spre masă (pentru a vă convinge încercați
varianta fără RC). Rezistența RC=1MΩ introdusă în paralel cu condensatorul asigură această
cale de curent fără a modifica practic funcționarea circuitului.

Circuit R-L-C serie

**** AC ANALYSIS TEMPERATURE = 27.000 DEG C

***************************************************************************
***

FREQ V(1) VP(1)

1.000E+03 1.000E+02 -1.063E-03

**** 03/30/16 17:45:18 *********** Evaluation PSpice (Nov 1999)

**************

Circuit R-L-C serie

**** AC ANALYSIS TEMPERATURE = 27.000 DEG C

***************************************************************************
***

FREQ V(R) VP(R) V(L) VP(L) V(C)

1.000E+03 1.000E+02 -1.242E-19 1.592E+02 9.000E+01 1.592E+02

**** 03/30/16 17:45:18 *********** Evaluation PSpice (Nov 1999)

**************

Circuit R-L-C serie

**** AC ANALYSIS TEMPERATURE = 27.000 DEG C

***************************************************************************
***

FREQ VP(C)

1.000E+03 -8.999E+01

JOB CONCLUDED

TOTAL JOB TIME 0.00

Rulați analiza de mai sus și pentru f1=500Hz și f2=2000Hz și comparați rezultatele.

Tot ca exercițiu schimbați alimentarea într-o sursă de tensiune sinusoidală de amplitudine 1V.
Observați că în acest caz rezistența RC în paralel cu C nu mai este necesară. De ce?

Ex1.4 Transferul maxim de putere

Transferul maxim de putere în curent continuu are loc pentru cazul în care rezistența de
sarcină este egală cu rezistența internă a sursei echivalente de tensiune. În cazul circuitelor de
curent alternativ, atât impedanța internă a sursei echivalente cât și impedanța de sarcină sunt
mărimi complexe. Se poate demonstra că într-o astfel de situație, transferul maxim de putere
are loc dacă impedanța de sarcină și impedanța internă a sursei sunt complex conjugate.
Figura 4 Circuit cu transfer maxim

Pentru circuitul din figura 4 de exemplu Vin are amplitudinea 10V și frecvența 1kHz iar
Ri=10Ω și Li=25.33mH. Atunci pentru ca transferul să fie maxim, trebuie ca Rl=10Ω și
Cl=1μF. De ce? Rulați următorul exemplu:

Transfer maxim de putere

Vin 1 0 AC 10
RI 1 2 10
LI 2 3 25.33M
RL 3 4 10
CL 4 0 1U
.AC LIN 1 1K 1K
.PRINT AC I(RL) IP(RL)
.END

Se observă I(Rl)=0.5A ceea ce conduce la o putere absorbită egală cu 2.5W.

Exemple pentru domenii de frecvențe

Ex2.1 Rezonanța RLC serie
Să analizăm circuitul RLC serie din figura 5 cu valorile de la exemplul 1.3. În acest caz
rezonanța tensiunilor are loc la frecvența:

f0=12πLC=999.3Hz

Figura 5 Circuit R-L-C serie

Vom analiza comportarea circuitului în gama de frecvențe cuprinse între 100Hz și 10kHz.
Rulați următorul program și urmați pașii de mai jos:

Rezonanta serie
Vin 1 0 AC 1
R 1 2 100
L 2 3 25.33m
C 3 0 1u
.AC LIN 1000 100Hz 10kHz
.PROBE
.END

Rulați programul

Se deschide editorul PROBE

Selectați Axis Settings

Selectați Log ca în figură

Selectați Add Trace

Selectați ca în figură

Se observă maximul lui I(R) la 1000Hz

Vom adăuga graficul fazei curentului

Apăsați Add Trace

Introduceți faza curentului

Se obțin graficele ca în figură

Apăsați Add Y Axis

Adăugați impedanța Z(ω)=V(1)/I(R)
 
Pentru a vedea cursorul, apăsați ca în figură

 1
 2
 3
 4
 5
 6
 7
 8
 9
 10
 11
 12
 13
 14

Activând cursorul ca în ultima imagine de mai sus, stabiliți valoarea impedanței

(Z(ω)=V(1)I(R)) și a fazei pentru 3 frecvențe: f1=500Hz, f0=1000Hz și f2=2000Hz. (Obs:
cursorul A1 se modifică cu butonul din stânga al mouseului iar cursorul A2 cu butonul din
dreapta)
Se remarcă că pentru f<f0, circuitul se comportă capacitiv, iar pentru f>f0, el se comportă
inductiv.

Filtre pasive
Filtrele pasive, conținând numai rezistoare, bobine și condensatoare, își găsesc numeroase
aplicații în practică. Cele mai simple filtre se obțin prin înserierea unui rezistor cu un
condensator.

Filtrul trece-jos și filtrul trece-sus

În figura 2 avem de fapt un filtru trece jos daca considerăm drept ieșire tensiunea pe
condensator și un filtru trece sus daca considerăm ieșirea tensiunea pe rezistor. Folosim
următorul program Spice:

Filtru trece-jos
Vin 1 0 AC 1
R 1 2 10k
C 2 0 10nF
.ac dec 10 1hz 1meghz
.probe
.end

Figura 6 Determinarea benzii de trecere a FTJ

Trasați și dreapta de valoare = 0.707 și notați frecvența de intersecție cu graficul. Aceasta se
numește frecvență de tăiere. (Obs: cursorul A1 se modifică cu butonul din stânga al mouseului
iar cursorul A2 cu butonul din dreapta)

Figura 7 Frecvența de tăiere

Pe un alt grafic reprezentați faza tensiunii de pe condensator, VP(2). Verificați cu ajutorul

celuilalt cursor că, la frecvența de tăiere faza este de -45°.

Ca un exercițiu, vă propunem analizarea într-un mod asemănător și a comportării filtrului

trece-sus (ieșirea pe rezistor).

Filtrul trece-bandă de tip Butterworth

Schema unui filtru trece-bandă de tip Butterworth este prezentată în figura 8.

Figura 8 Filtrul trece-bandă de tip Butterworth

Se folosește următorul program:

Filtru trece-banda
*de tip Butterworth
Vin 1 0 ac 1
l12 1 2 100u
c23 2 3 2u
c30 3 0 50u
l30 3 0 4u
r30 3 0 1
.ac dec 1000 5k 25k
.probe
.end

După rulare afișați curba V(3). Banda de trecere se determină citind coordonatele punctelor de
intersecție cu dreapta 0.707. Se obține B=2.252kHz.
Figura 9 Banda de trecere a filtrului trece-bandă

Filtrul oprește-bandă

Schema unui filtru oprește-bandă este prezentată în figura 10.

Figura 10 Filtru oprește-bandă

Se folosește următorul program:

Filtru opreste-banda
Vin 1 0 AC 1
R12 1 2 10
R23 2 3 0.5
C34 3 4 26.5U
L40 4 0 265M
R20 2 0 10
.ac OCT 100 40 80
.probe
.end
După rulare afișați curba V(2). Frecvențele de tăiere se determină citind coordonatele
punctelor de intersecție cu dreapta 0.707*500mV deoarece amplitudinea în benzile de trecere
este de 500mV. Se obțin f1=58.4Hz și f2=61.7Hz.

Figura 11 Filtrul oprește-bandă

Probleme
Găsiți curenții (modul și fază) prin laturile următoarelor circuite folosind PSpice (pentru toate
circuitele frecvența este f=50Hz):

Problema 1.1

Se dau: L1=100πmH, L2=300πmH, C=500πμF, R=10Ω, V1=20sin(ωt−π4)[V],

V2=60sin(ωt+π4)[V]
Figura 12 Problema 1.1

Problema 1.2

Se dau: L1=200πmH, L2=100πmH, C=1000πμF, R=10Ω, V1=20*sqrt(2)*sin(ωt−π2)[V],

V2=20sin(ωt+3π4)[V]

Figura 13 Problema 1.2

Problema 1.3

Se dau: L=100πmH, C=250πμF, R1=20Ω, R2=10Ω, R3=20Ω, V1=40sin(ωt+π4)[V],

V2=80sin(ωt+π4)[V]

Figura 14 Problema 1.3

Concluzii
În această lecție am analizat circuite analogice în funcție de frecvență. Am considerat atât
cazul în care frecvența este unică, cât și cazul în care frecvența baleiează un interval.

În lecția următoare vom studia răspunsul în timp al circuitelor, adică regimul tranzitoriu
(TRANsient analysis).
Analiza circuitelor în regim tranzitoriu
Cuprinsul lecţiei: 4

 Ce este regimul tranzitoriu?

 Cum se declară?
 Tipuri de surse
 Probleme cu condiții inițiale
 Fazori - timp
 Regim tranzitoriu - regim permanent
 Filtre
 Exerciții și întrebări
 Concluzii

Ce este regimul tranzitoriu?

Până în acest moment la laborator am studiat utilizarea programului PSpice pentru analiza de
curent continuu și pentru analiza în fecvență. Acum vom studia analiza circuitelor în funcție
de timp (TRANsient Analysis), adică analiza tranzitorie a circuitelor.

Vorbim despre regim tranzitoriu și în situația în care în circuit are loc o schimbare a
parametrilor, de exemplu închiderea unui întrerupător, modificarea tensiunii unei surse etc și
datorită acesteia se trece de la o stare de echilibru a circuitului la alta (stările inițială și finală).
Teoretic starea finală este atinsă după un timp infinit dar în practică se consideră că după 3
constante de timp (vom vedea ce înseamnă constantă de timp) regimul tranzitoriu s-a încheiat
și că s-a ajuns la starea de echilibru finală.

Pentru rezolvarea analitică a circuitelor de regim tranzitoriu, preponderent se folosește metoda

operațională (a Tranformatei Laplace), după cum vom vedea la seminar.

Pentru început vom vedea cum se declară sursele de curent și de tensiune având anumite
forme în timp. Apoi vom vedea niste exemple de probleme în care ne interesează evoluția în
timp a mărimilor.

Este destul de mult de muncă în acest laborator, așa că luați chestiunile pe rând și ajungeți cât
de departe puteți. O temă importantă o reprezintă problemele cu condiții inițiale. Spor la
lucru!

Cum se declară comanda de analiza tranzitorie?

Analiza regimului tranzitoriu se formulează cu comanda ".TRAN". Sintaxa ei este:

.TRAN pas_afisare moment_final [moment_inceput [pas_max]] [UIC]

Această comandă va face analiza circuitului în domeniul timp de la tinitial=0 până la

tfinal=momentfinal. Spice folosește un pas intern de calcul care este ajustat automat. Valoarea
maximă a pasului intern este implicit momentfinal50, în cazul în care nu se specifică pasmax.
Valoarea pasafisare este folosită de Spice pentru a scrie (a afișa) rezultatele analizei în fișierul
de ieșire. Dacă pasafisare=momentfinal se vor considera la afișare toate punctele calculate.
Însă pentru grafice (programul PROBE) se poate specifica un momentinceput. Cuvântul cheie
opțional UIC provine de la Use Initial Conditions și indică prezența unor condiții inițiale ce
trebuie luate în considerare la începutul analizei regimului tranzitoriu (atunci când se folosește
cuvântul cheie IC la condensatoare și bobine - IC provine de la Initial Conditions).

*Ex1: analiza se termină la 1s și are pasul de afișare de 0.1ms:

.TRAN 0.1ms 1s
*Ex2: analiza se termină la 1s, are pasul de afișare de 0.1ms.
*Rezultatele sunt afișate începând cu 5ms:
.TRAN 0.1ms 1s 5ms
*Ex3: analiza se termină la 1s, are pasul maxim de integrare 0.05ms
*și pasul de afișare de 0.1ms. Rezultatele sunt afișate
*începând cu 5ms și sunt folosite condițiile inițiale:
.TRAN 0.1ms 1s 5ms 0.05ms UIC
*Ex4: analiza se termină la 1s, sunt afișați toți pașii calculați:
.TRAN 1s 1s

Tipuri de surse folosite în analiza de regim tranzitoriu

Pentru sursele de tensiune și respectiv de curent a căror expresie primește ca argument timpul,
pot fi folosite următoarele declarații:

Enume nod+ nod- VALUE={expresie}

Gnume nod- nod+ VALUE={expresie}

În cadrul expresiei pot fi folosiți operatorii +,-,*,/,(,) iar ca variabilă independentă este timpul
(time).

De exemplu pentru tensiunea de forma e(t)=1+2e−3t se folosește următoarea declarație:

E 1 0 value={1+2*exp(-3*time)}

Pentru curentul de forma i(t)=15cos(1000t+π6)[mA] se folosește următoarea declarație:

G 2 0 value={0.015*cos(1000*time+30*3.14/180)}

Am folosit literele E și G, aceste surse sunt surse comandate deoarece pot depinde și de alte
potențiale electrice din circuit, nu numai de timp.

Alte tipuri de surse sunt:

 PWL - de la PieceWise Linear - pentru semnale aperiodice cu variație liniară pe

porțiuni
 SIN - pentru semnale sinusoidale
 EXP - pentru semnale exponențiale
 PULSE - pentru impulsuri periodice
 SFFM - pentru semnale modulate în frecvență

Sursa PWL
Sursa PWL are următoarea sintaxă:

PWL(t1,v1,t2,v2,...,tn,vn)

Se observă că semnalul este dat prin perechi (ti,vi).

Ca exemplificare, să urmăm pașii de mai jos:


Introduceți codul din figură

Se activează și se simulează circuitul

Pornește programul PROBE

Apăsați Add Trace

Selectați V(1)
 
Se obține această formă

 1
 2
 3
 4
 5
 6

Se observă că în afară de literele folosite pentru multipli și submultipli, unitățile de măsură

sunt ignorate. Deci dacă vom scrie mV, V va fi ignorat reținându-se doar submultiplul m
(10−3).

Sursa SIN

Sursa SIN are următoarea sintaxă:

SIN(v_decalaj,v_amplitudine,frecventa,intarziere,factor_amortizare,faza)

Parametrii de mai sus au următoarele semnificații:

 v_decalaj - valoarea de decalaj (offset)

  v_amplitudine - amplitudinea semnalului
 frecventa - frecvența semnalului
 intarziere - timpul de intârziere
 factor_amortizare - dacă amplitudinea descrește
 faza - faza în grade

Sursa va începe (pentru t∈(0,intarziere)) cu valoarea:

=vdecalaj+vamplitudine*sin(2πfaza360).

și va continua cu expresia:

=vdecalaj+vamplitudine*e(t−intarziere)*factoramortizaresin(2π*frecventa*(t−intarziere)+2πf
aza360).

Ca exemplificare, să urmăm pașii de mai jos:


Introduceți codul din figură

Pornește programul PROBE

Apăsați Add Trace

Selectați V(1)
 
Se obține această formă

 1
 2
 3
 4
 5

Se observă din nou că în afară de literele folosite pentru multipli și submultipli, unitățile de
măsură sunt ignorate. Deci dacă scriem V, Hz, s, ele vor fi ignorate, dar folosindu-le avem
avantajul lizibilității codului.

Sursa EXP

Sursa EXP are următoarea sintaxă:

EXP(v_initiala,v_varf,intarz_crestere,const_crestere,intarz_descrestere,con
st_descrestere)

Parametrii de mai sus au următoarele semnificații:

 v_initiala - valoarea inițială

 v_varf - valoarea de varf
  intarz_crestere - momentul când începe frontul anterior
 const_crestere - constanta de timp a frontului anterior
 intarz_descrestere - momentul când începe frontul posterior
 const_descrestere - constanta de timp a frontului posterior

Ca exemplificare, să urmăm pașii de mai jos:


Introduceți codul din figură
 
Se obține această formă

 1
 2

Din slide-ul 2 din figura anterioară, să lămurim ce înseamnă constantă de timp. Aceasta
reprezintă intervalul de timp măsurat de la pornirea frontului anterior/posterior, după
scurgerea căruia variaţia mărimii respective până la valoarea sa de regim permanent va fi de
"e" ori mai mică decât variatia totală. În practică se consideră că regimul tranzitoriu se încheie
după 3 constante de timp.

Cât timp înseamnă 3 constante de timp pentru frontul anterior de mai sus? Dar pentru cel
posterior?

Sursa PULSE

Sursa PULSE descrie un tren de impulsuri și are următoarea sintaxă:

PULSE(v_initiala,v_puls,durata_crestere,durata_descrestere,durata_puls,peri
oada)

Pentru a vedea semnificația parametrilor de mai sus, să urmăm pașii:


Introduceți codul din figură
 
Se obține această formă

 1
 2

Sursa SFFM (Single Frequency Frequency Modulated Waveform)

Sursa SFFM descrie o formă de undă modulată în frecvență și are următoarea sintaxă:

SFFM(v_decalaj,v_amplitudine,frecv_purtătoare,factor_modulatie,frecv_modula
toare)

Parametrii de mai sus au următoarele semnificații:

 v_decalaj - valoarea de decalaj (offset)

 v_amplitudine - valoarea amplitudinii
 frecv_purtatoare - frecvența purtătoarei
 factor_modulație - coeficient ce măsoară modulația
 frecv_modulatoare - frecvența undei modulatoare

Sursa va avea expresia:

=vdecalaj+vamplitudine*sin(2π*frecvpurtatoare*(t−factormodulatie*sin(2π*frecvmodulatoar
e*t))).

Ca exemplificare, să urmăm pașii de mai jos:


Introduceți codul din figură
 
Se obține această formă

 1
 2

Se observă că unda sinusoidală prezintă variații ale perioadei. Spunem ca unda purtătoare este
modulată în frecvență deoarece frecvența ei depinde de frecvența undei modulatoare.
Modulația FM se folosește și în cazul posturilor de radio analogice din banda de frecvențe
ultrascurte și în cazul televiziunii analogice terestre.

Probleme cu condiții inițiale

De obicei, aceste probleme se referă la circuite ce conțin întrerupătoare care la momentul
inițial se deschid sau se închid. Aceasta înseamnă că trebuie determinate condițiile inițiale
(fișier Spice separat) iar apoi în simularea de regim tranzitoriu (fișier Spice separat) trebuiesc
incluse aceste condiții inițiale. Condițiile inițiale sunt tensiunile pe condensatoare și curenții
prin bobine la momentul inițial.

Practic rezolvarea unei astfel de probleme necesită rezolvarea unui circuit pentru aflarea
condițiilor inițiale și apoi simularea propriu-zisă de regim tranzitoriu.

În acest ultim circuit condițiile inițiale pentru bobine și condensatoare sunt precizate folosind
cuvântul cheie IC ca în exemplele de mai jos:
C 20 25uF ic=5V
L3 2 0 15H IC=2.308A

Deasemenea în cadrul comenzii .tran trebuie folosit cuvântul cheie UIC (Use Initial
Conditions).

Să analizăm un caz concret. Fie circuitul:

Figura 1 Circuit cu întrerupător (condiții inițiale)

Se dau: E=90V, R=5Ω, L=62.5mH și C=100μF.

Programul pentru aflarea condițiilor inițiale este dat mai jos:

Figura 2 Programul pentru aflarea condițiilor inițiale

Se obțin UC(0)=90V și IL(0)=0A. Simularea propriu-zisă de regim tranzitoriu este dată mai
jos (după ce a fost închis întrerupătorul K):
Figura 3 Programul de regim tranzitoriu

Se obțin următoarele variații ale curentului prin bobină și a tensiunii pe condensator:

Figura 4 Rezultat regim tranzitoriu

Reprezentarea rezultatelor unor analize fazoriale sub
formă grafică
Să presupunem că avem un sistem trifazat de tensiuni dat de următorii fazori:

V=1218.82ej7.2°

V=2218.82e−j112.8°

V=3218.82ej127.2°

Pentru a afișa variația în timp a tensiunilor, să folosim următorii pași:


Introduceți codul din figură
 
Se obține evoluția celor 3 tensiuni trifazate

 1
 2

Diferența dintre regimul permanent și cel tranzitoriu

Fie circuitul R-L serie din figură alimentat de o sursă sinusoidală:
Figura 5 Circuit R-L serie

Aici vin=2sin(ωt) și f=100Hz. Ne întrebăm cât este curentul prin circuit.

Să simulăm circuitul mai întâi în curent alternativ:

Figura 6 Introduceți codul din figură.

Se obține următorul fișier de ieșire:

**** 05/01/15 12:15:27 *********** Evaluation PSpice (Nov 1999)

**************

circuit R-L serie

**** CIRCUIT DESCRIPTION

***************************************************************************
***

Vin 1 0 AC 1V
R1 1 2 10
L1 2 0 10mH
.AC LIN 1 100Hz 100Hz
.print ac I(R1) IP(R1)
.end

**** 05/01/15 12:15:27 *********** Evaluation PSpice (Nov 1999)

**************

circuit R-L serie

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG C

***************************************************************************
***

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 0.0000 ( 2) 0.0000

VOLTAGE SOURCE CURRENTS

NAME CURRENT

Vin 0.000E+00

TOTAL POWER DISSIPATION 0.00E+00 WATTS

**** 05/01/15 12:15:27 *********** Evaluation PSpice (Nov 1999)

**************

circuit R-L serie

 **** AC ANALYSIS TEMPERATURE = 27.000 DEG C

***************************************************************************
***

FREQ I(R1) IP(R1)

1.000E+02 8.467E-02 -3.214E+01

JOB CONCLUDED

TOTAL JOB TIME .03

Deci modulul curentului este aproximativ 0.084A iar faza inițială este -32°.

Să vedem acum diferența dintre regimul tranzitoriu și regimul permanent (sinusoidal) de mai
sus. Pentru aceasta considerăm un circuit cu două porțiuni: o porțiune (nodurile 0, 1 și 2) care
se alimentează la momentul 0 cu sursa E cu parametrii AC determinați mai sus, deci avem un
curent tranzitoriu pe care îl vom afișa (vedeți slide-ul 3 din figura de mai jos). Cealaltă
porțiune de circuit (nodurile 3 și 0) simulează regimul permanent folosind sursa G. Diferența
dintre cei doi curenți ne va da influența regimului tranzitoriu (aproape de momentul 0s). Se
observă că pentru momente de timp mai mari cei doi curenți se suprapun, ceea ce era de
așteptat.

Introduceți codul din figură

Apăsați Add Trace și introduceți cele 3 curbe ca în figură
 
Se obține cu verde raspunsul tranzitoriu, cu roșu, cel permanent și cu albastru diferența
lor

 1
 2
 3

Deoarece la momentul 0 curentul prin rezistorul R este 0, urmează regimul tranzitoriu (cu
verde), așa cum se vede în ultimul pas de mai sus. Curentul în regim permanent (cu roșu) are
o valoare bine determinată și este simulat prin sursa G. Diferența lor este reprezentată cu
albastru.

Filtre în regim tranzitoriu

În laboratorul precedent am studiat analiza în frecvență și ca aplicație, anumite tipuri de filtre.
Am vazut caracteristicile filtrelor, adică ce benzi de frecvență filtrează. Filtrele pot fi studiate
însă și în domeniul timp aplicând un impuls treapta unitate la intrare și observând cum este
transformat acesta la ieșire.

Vom studia filtrul trece-sus, simularea pentru filtrul trece-jos rămânând să o faceți voi. Se
folosește următorul circuit (circuit R-C serie):
Figura 7 Circuit R-C serie

Intrarea este sursa vin dar ieșirea diferă în funcție de tipul filtrului. Pentru filtrul trece-sus,
ieșirea este tensiunea pe rezistor V(1,2). Pentru filtrul trece-jos ieșirea este tensiunea pe
condensator V(2,0). Intuitiv aceasta era de așteptat deoarece condensatorul se comportă la
frecvențe joase ca o întrerupere iar pentru frecvențe ridicate, ca un scurt.

Filtrul trece-sus (circuit de derivare)

În acest caz tensiunea de ieșire este tensiunea pe rezistor. Analitic, ea are expresia:

Vout=Vin*e−tτ

τ este constanta de timp și este egală cu R1*C1. Vom urma pașii de mai jos:

Introduceți codul din figură

Rulați pe rând cele două analize

După ce ați rulat cele 2 analize, selectați PLOT - Transient


Add Traces V(1) - observați semnalul treaptă

Măriți fereastra și apăsați Add Plot to Window


Apare un grafic nou și apoi apăsați Add trace

Add Traces V(2)


Observați răspunsul la semnalul treaptă

Apăsați Window - New Window


Selectați Plot - AC

Add Trace V(2)


Observați răspunsul filtrului în frecvență

 1
 2
 3
 4
 5
  6
 7
 8
 9
 10
 11
 12

În cazul filtrului trece-jos (circuit de integrare) tensiunea de ieșire este tensiunea pe

condensator. Analitic, ea are expresia:

Vout=Vin*(1−e−tτ)

Exerciții și întrebări

Figura 8 Exercițiul 1

1. Pentru circuitul din figură (la t<0 întrerupătorul K este deschis iar la t=0 întrerupătorul K se
închide), scrieți fișierul SPICE pentru determinarea condițiilor inițiale. Scrieți apoi fișierul
SPICE folosit pentru analiza de regim tranzitoriu a variației curentului prin bobină şi a
variației tensiunii la bornele condensatorului, de la 0s până la 8ms, cu pasul de timp 0.01ms.
Se dau: R1=400Ω, R2=800Ω, L2=0.2H, C3=2.5μF și E1=60V

2. Rulați programul pentru filtrul trece-sus prezentat anterior pentru R1=1Ω și apoi pentru
R1=100Ω. Ce modificări apar în domeniul timp și în domeniul frecvență?

3. Rulați programul pentru filtrul trece-sus pentru un impuls dreptunghiular, de exemplu:

Vin 1 0 AC 1v pwl(0,0 0.2m,0 0.2001m,1 0.4m,1 0.4001m,0 1m,0)

4. Rulați programul pentru filtrul trece-sus pentru un tren de impulsuri, de exemplu:

Vin 1 0 AC 1v pwl(0,0 0.001m,1 0.2m,1 0.2001m,0 0.5m,0 0.5001m,1 0.7m,1

+0.7001m,0 1m,0 1.001m,1 1.2m,1 1.2001m,0 1.5m,0)
.tran 0.01m 1.5m
5. Analizați filtrul trece-jos similar cum ați făcut pentru filtrul trece-sus anterior dar de data
aceasta ieșirea este tensiunea pe condensator.

Concluzii
În această lecție am văzut cum se simulează circuitele în domeniul timp. Am văzut diferitele
tipuri de surse ce pot apărea, probleme cu condiții inițiale (Atenție!), reprezentarea unor
mărimi fazoriale în domeniul timp, comparația între regimul permanent și regimul tranzitoriu
și răspunsul în timp al filtrelor trece-sus și trece-jos