LUPU GEORGE

442B

Laborator 1 Procesoare Electronice de putere

Modelarea Spice a surselor de C.C. in comutatie

1. Obiectul aplicatiei

Aplicația își propune să faciliteze atât înțelegerea funcționării convertoarelor c.c.-c.c. în comutație, cât și
familiarizarea cu particularitățile modelarii și analizei SPICE pentru această categorie de convertoare. Sunt prezentate
topologiile de bază ale convertoarelor neizolate: Buck, Boost, Buck-Boost si Cuk, topologii de convertoare izolate:
forward si flyback, precum și modalitatea de analiză a raspunsului în timp al unei surse în comutație având la bază
convertorul forward.

2. Introducere teoretica
Schema bloc a unei surse de curent continuu în comutație este următoarea:

Elementul de bază este convertorul c.c.-c.c. în comutație, care are ca elemente principale:

• comutatorul activ SW (comutator static), care este comandat cu factorul de comandă d = tC / T, deci conduce un
interval de durată tC în cadrul unei perioade T;
• comutatorul pasiv realizat cu dioda D, care are rolul de a asigura o cale de conducție a curentului atunci când
comutatorul SW este blocat;
• o inductanță L, cu rol de acumulare a energiei și un condensator de filtraj C, pentru filtrarea tenisunii de ieșire.

Raportul de transformare uo/u1 este funcție de factorul de comandă d = tC/T, funcție carcateristică fiecărui tip
de convertor.

Circuitul de comandă prezentat în figura de mai sus realizează comanda cu control în tensiune, adică factorul de
comandă d este funcție de tensiunea de eroare uε = f (UREF-kuo).
3. Desfasurarea aplicatiei

Convertorul Buck

Schema convertorului Buck este urmatoarea:

PWM_RAMP este circuitul de comanda.

Functionarea convertorului Buck:

• Intervalul (0, DT) - In acest interval comutatorul XSW este in conductie. Inductantei L i se aplica tensiunea (UI - Uo).
Inductanta acumuleaza energie iar curentul creste de la Im la IM. Tot in acest interval se face transfer direct de
energie in condensatorul de filtraj si sarcina
• Intervalul (DT, T). Comutatorul Xsw este blocat. Dioda XD este deschisă datorită tensiunii de autoinducție care
apare la bornele inductanței L atunci când XSW trece în blocare și curentul prin L incepe să scadă. Circulația de
curent se face deci prin L, XD, C și sarcină. Inductanței L i se aplică tensiunea (-Uo), astfel încât aceasta cedează
energie către sarcină.
• Convertorul funcționează în modul de conducție continuă dacă il, curentul prin inductanța L, nu se anulează în
decursul unei perioade de comutație. Avem relația: (UI - UO)DT = UO(1-D)T de unde se obține UO/UI = D, deci
raportul de transformare al acestui convertor este întotdeauna subunitar, de aici vine denumirea de convertor
coborâtor de tensiune.
Fisierul de circuit este urmatorul:

* Modelul convertorului Buck

.LIB C:\PSPICE\L6\L6.LIB
* Parametrii transmisi subcircuitului PWM_RAMP
.PARAM RISE=9.8u FALL=0.1u PW=0.1u T=10u
* Sursa de tensiune care impune factorul de comanda D
VCNTL 10 0 0.75V
* Circuitul de comanda
XLOGIC 10 0 11 PWM_RAMP
* Convertorul Buck propriu-zis
VI 1 0 8V
XSW 1 2 11 0 SWITCH
XD 0 2 SW_DIODE_WITH_SNUB
L 2 3 5uH IC=9A
C 3 0 100uF IC=5.5V
RS 3 0 0.5
.PROBE
.TRAN 100.000n 200.000u 150.000u 100.000n UIC .OPTIONS ITL5 = 0 .END
.OPTIONS ITL5=0
.END
BUCK-CCM
Fisierul de circuit corespunzator BUCK_CCM.cir:
* Modelul convertorului Buck
* Functionare in mod de conductie continua
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
*
VCONTL 50 0 0.75V
XLOGIC 50 0 52 PWM_RAMP
*
XSW 1 2 52 0 SWITCH
XD 0 2 SW_DIODE_WITH_SNUB
*
L 2 3 5U IC=9A
C 3 0 100UF IC=5.5V
RLOAD 3 0 0.5
*
VD 1 0 8V
.PROBE
.TRAN 100.000N 100.000U 50.000U 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END
Parametri afișați:
• Tensiunea de ieșire v(3)
• Tensiunea pe inductanța L v(2,3)

Curentul prin condensatorul C, I(c)

• Curentul prin inductanta L, I(l)

• Curentul prin sarcina, I(RS)

a)
L=5μH, C=100μF, RS=2Ω
D = tc / T, (D = raport de conducție)
T = tb + tc (T = perioada de comutație , tb = timpul de blocare tc = timpul de conducție)
tb = 2.58 μs, tc = 7,41 μs
T = 7,41 μs + 2,58 μs = 10 μs
D = tc/T = 7.41/10=0.741
b) IL, curentul prin inductanta L nu se anuleaza in decursul unei perioade de comutatie, deci convertorul
functioneaza in modul de conductie continua.
Im = 9,148 A ≠ 0
IM = 12,237 A
∆I = riplul curentului
∆Imas = IM - Im = 12,237 - 9,148 = 3,089 A
∆Iteoretic = IM - Im = D(1-D)T/2 x UI = [0.741 * (1-0, 0.741) * 10]/ 5 * 8V = 3.07 A
Valorile sunt aproximativ egale.
 Valoarea maxima a riplului are loc pentru D = 0.5, ∆Imax = 4A

IL = valoarea medie a curentului prin bobina

IL = (T x ∆I)/2 + T * Im = T(IM - Im)/2 + T * Im = (IM + Im)/2 = (12,237 + 9,148)/2 = 10,6925 A

• curentul pe dioda XD, v(2)

UO = tensiunea de ieșire sau riplu absolut

UO,măs = 5,36 V
UO,teoretic = D x UI = 0,741 x 8V = 5.928 V

Tensiunea de iesire, v(3):

∆UOmas = UOM – UOm = 5.3261 V - 5.2896 V = 36.5 mV

∆UOteoretic = [T^2 * D * (1 – D) * UI] / (L * C * 8) = [100 * 0.75 * (1 – 0.75) * 8] / (5 * 100 * 8) = 37.5 mV

BUCK-ESR
d)

Fișierul de circuit corespunzător circuitului BUCK_ESR.CIR:

* Modelul convertorului Buck
* Functionare in mod de conductie continua.
* Condensator de filtraj cu rezistenta echivalenta serie ESR nenula
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
*
VCONTL 50 0 0.75V
XLOGIC 50 0 52 PWM_RAMP
*
XSW 1 2 52 0 SWITCH
XD 0 2 SW_DIODE_WITH_SNUB
*
L 2 3 5U IC=9A
C 3A 0 100UF IC=5.5V
RESR 3 3A 100M
RLOAD 3 0 0.5
*
VD 1 0 8V
.PROBE
.TRAN 100.000N 100.000U 50.000U 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END
Parametri afisati:

• Tensiunea de iesire, v(3)

• Tensiunea pe condensatorul C, v(3a)
• Tensiunea pe rezistenta echivalenta serie, v(3, 3a)

Valoarea riplului introdus de ESR-ul condensatorului C: ∆Uo = 0,25 V

e) K = 2L / (RS*T) = 10μH / (0.5Ω * 10μs) = 0.5

D = 1 – K (condiția de graniță)
RSlim = 2L / ((1-D)T) = 2 x 5 μH / ((1-0,75) x 10 μs) = 4 Ω

RSDCM = (2 * L) / [(K * T) = 10μH / (0.5 * 10μs) = 2Ω

BUCK DCM

f)

Fișierul de circuit corespunzător circuitului BUCK_DCM.CIR:

* Modelul convertorului Buck
* Functionare in mod de conductie discontinua
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
*
VCONTL 50 0 0.75V
XLOGIC 50 0 52 PWM_RAMP
*
XSW 1 2 52 0 SWITCH
XD 0 2 SW_DIODE_WITH_SNUB
*
L 2 3 5U IC=5A
C 3 0 100UF IC=5.5V
RLOAD 3 0 4
*
VD 1 0 8V
.PROBE
.TRAN 100.000N 100.000U 50.000U 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END

Parametrii afisati:
• Tensiunea pe inductanta L, v(2,3)
• Tensiunea de iesire V(3)
• Valoarea medie a tensiunii de iesire
 • curentul prin inductanta L, I(l)
• curentul prin condensatorul C, I(c)
• curentul prin rezistenta de sarcina, I(rload)

Observam ca avem un interval pe forma de unda in care curentul este egal cu 0, deci convertorul este in regim
discontinuu.

Tc = D * T = 7.3146μs

Tb = D2 * T = 1.2785μs

T – Tc – Tb = T – D * T – D2 * T = 1.3036μs

T = 1.3036 μs + Tc + Tb = 1.3036μs + 7.3146μs + 1.2785μs = 9.8967μs

D = Tc / T = 7.3146μs / 9.8967μs = 0.739

D2 = Tb / T = 1.2785μs / 9.8967μs = 0.1291

K = (2 * L) / (RS * T) = 10μH / (0.5Ω * 10μs) = 0.5

(UO / UI) |DCM = 2 / {1 + sqr[1 + (4 * K / D2)]} = 2 / {1+ sqr[1+ (2 / 0.546121)]} = 0.633

g) Forma de unda a tensiunii pe dioda XD, V(2)

Convertorul BOOST
3.3

Schema convertorului BOOST este urmatoarea:

Functionarea convertorului BOOST:

• În analiza funcționării se va considera că tensiunea pe condensatorul de filtraj este constantă și egală cu UO.
• Intervalul (0, DT). În acest interval comutatorul XSW este în conducție. Inductanței L i se aplică tensiunea UI.
nductanță acumulează energie iar curentul crește de la Im la IM. În acest interval nu se face transfer de energie
de la sursă de alimentare la sarcină. Tensiunea pe sarcină este menținută constantă de către condensatorul de
filtraj C.

• Intervalul (DT, T). La momentul DT comutatorul XSW trece în blocare iar curentul prin L începe să scadă. Dioda
XD se deschide, fiind polarizată direct datorită tensiunii de autoinducție care apare la bornele inductanței L. Se
poate remarca faptul că tensiunea de autoinducție pe inductanță L este negativă, astfel încât tensiunea care se
aplică la bornele sarcinii este mai mare decât tensiunea de alimentare UI. Raportul de transformare al acestui
convertor este, deci, supraunitar. În acest interval, inductanței L i se aplică tensiunea (UI – UO) < 0, astfel încât
curentul prin ea scade de la IM la Im. Inductanță cedează energie sarcinii și condensatorului de filtraj C.
Fisierul de circuit este urmatorul:

* Modelul convertorului Boost

.LIB C:\PSPICE\L6\L6.LIB
* Parametrii transmisi subcircuitului PWM_RAMP
.PARAM RISE=9.8u FALL=0.1u PW=0.1u PERIOD=10u
* Sursa de tensiune care impune factorul de comanda D
VCNTL 10 0 0.75V
* Circuitul de comanda
XLOGIC 10 0 11 PWM_RAMP
* Convertorul Boost propriu-zis
VI 1 0 7V
XSW 2 0 11 0 SWITCH
XD 2 2a SW_DIODE_WITH_SNUB
VIXD 2a 3 ; pentru vizualizarea curentului prin XD
*
L 1 2 10uH IC=10A
C 3 0 20uF IC=24v
RS 3 0 8
*
.PROBE
.TRAN 100.000n 200.000u 150.000u 100.000n UIC
.OPTIONS ITL5 = 0
.END
 Fișierul de circuit corespunzător circuitului BTS_CCM.CIR:
* Modelul convertorului Boost
* Functionare in mod de conductie continua
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
*
VCONTL 50 0 DC .75 ; *IPSP*
XLOGIC 50 0 52 PWM_RAMP
*
XSW 2 0 52 0 SWITCH
XD 2A 3 SW_DIODE_WITH_SNUB
VIXD 2 2A
*
L 1 2 10U IC=10A
C 3 0 20UF IC=24V
RS 3 0 8
*
VD 1 0 DC 7 ; *IPSP*
.PROBE
.TRAN 100.000N 100.000U 50.000U 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END

Parametri afisati:
• Tensiunea de iesire, V(3)
• Tensiunea pe inductanta L, V(1,2)

• Curentul prin inductanta L, I(l)

• Curentul prin condensatorul C, I(c)
• Curentul prin sarcina, I(RS)
b) Curentul prin dioda XD, I(VIXD):
c) Fisierul BTS_DCM.cir

Fișierul de circuit corespunzător circuitului BTS_DCM.CIR:

* Modelul convertorului Boost

* Rezistenta de sarcina isi modifica brusc valoarea
* de la 8 ohmi la 100 ohmi.
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
*
VCONTL0 50 0 DC .75 ; *IPSP*
XLOGIC 50 0 52 PWM_RAMP
*
XSW 2 0 52 0 SWITCH
XD 2A 3 SW_DIODE_WITH_SNUB
VIXD 2 2A
*
L 1 2 10U IC=10A
C 3 0 20UF IC=24V
RS 3 3A 8
RS1 3A 0 92
.MODEL SWITCH1 VSWITCH(RON=1M VON=1 ROFF=1MEG VOFF=0)
SW1 3A 0 3B 0 SWITCH1
VSW 3B 0 PULSE(0 1 0 1U 1U 20U 100U)
*
VD 1 0 DC 7 ; *IPSP*
.PROBE
.TRAN 100.000N 150.000U 0 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END
 Parametrii afisati:

• Tensiunea de iesire, V(3)

• Tensiunea pe inductanta L, V(1,2)

• Curentul prin inductanta L, I(l)

Convertorul Buck-Boost

Schema convertorului Buck-BOOST este urmatoarea:

• În analiza funcționării se va considera că tensiunea pe condensatorul de filtraj este constantă și egală cu UO.
• Intervalul (0, DT). În acest interval comutatorul XSW este în conducție. Inductanței L i se aplică tensiunea UI.
Curentul crește de la Im la IM iar inductanță L acumulează energie. În acest interval nu se face transfer de
energie de la sursă de alimentare la sarcină. Tensiunea pe sarcină este menținută constantă de către
condensatorul de filtraj C.
• Intervalul (DT, T). La momentul DT comutatorul XSW trece în blocare iar curentul prin L începe să scadă. Dioda
XD se deschide, fiind polarizată direct datorită tensiunii de autoinducție care apare la bornele inductanței L.
Tensiunea pe inductanța L, care în acest interval este chiar tensiunea de ieșire, este negativă. O primă concluzie
este că acest tip de convertor permite obținerea unei tensiuni negative față de masă. în acest interval
inductanței L i se aplică tensiunea UO < 0, astfel încât curentul prin ea scade de la IM la Im. Inductanță cedează
energie sarcinii și condensatorului de filtraj C.
 Fisierul de circuit:
* Modelul convertorului Buck-Boost
.LIB C:\PSPICE\L6\L6.LIB
* Parametrii transmisi subcircuitului PWM_RAMP
.PARAM RISE=9.8u FALL=0.1u PW=0.1u T=10u
* Factorul de comanda D
VCNTL 10 0 0.75V
* Circuitul de comanda
XLOGIC 10 0 11 PWM_RAMP
* Convertorul propriu-zis
VI 1 0 10V
XSW 1 2 11 0 SWITCH
XD 2a 2 SW_DIODE_WITH_SNUB
VIXD 3 2a ;pentru vizualizarea curentului prin XD
L 2 0 10uH IC=3.75A
C 3 0 100uF IC=-24v
RS 3 0 8
.PROBE
.TRAN 100.000n 100.000u 50.000u 100.000n UIC
.OPTIONS ITL5 = 0
.END

Fișierul de circuit corespunzător circuitului BB_CCM.CIR:

* Modelul convertorului Buck-Boost
.lib c:\pspice\l6\l6.lib
* Parametrii transmisi subcircuitului PWM_RAMP
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
* FACTORUL DE COMANDA D
VCONTL 50 0 0.75V
* CIRCUITUL DE COMANDA
XLOGIC 50 0 52 PWM_RAMP
* CONVERTORUL PROPRIU-ZIS
VD 1 0 10V
XSW 1 2 52 0 SWITCH
XD 2A 2 SW_DIODE_WITH_SNUB
VIXD 3 2A ;PENTRU VIZUALIZAREA CURENTULUI PRIN XD
L 2 0 10U IC=3.75A
C 3 0 100UF IC=-24V
RS 3 0 8OHMI
*
.PROBE
.TRAN 100.000N 100.000U 50.000U 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END
 Parametrii afisati:
• Tensiunea de iesire, V(3)
• Tensiunea pe inductanta L, V(2)

• Curentul prin inductanta L, I(l)

• Curentul prin condensatorul C, I(c)
• Curentul prin sarcina, I(RS)
c) Curentul prin dioda XD, I(VIXD):

d)

Fișierul de circuit corespunzător circuitului BB_DCM.CIR:

* Modelul convertorului Buck-Boost
.LIB C:\PSPICE\L6\L6.LIB
* Parametrii transmisi subcircuitului PWM_RAMP
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
* Factorul de comanda D
VCONTL 50 0 DC .2 ; *IPSP*
* Circuitul de comanda
XLOGIC 50 0 52 PWM_RAMP
* Convertorul propriu-zis
VD 1 0 10V
XSW 1 2 52 0 SWITCH
XD 2A 2 SW_DIODE_WITH_SNUB
VIXD 3 2A ;PENTRU VIZUALIZAREA CURENTULUI PRIN XD
L 2 0 10U IC=0
C 3 0 100UF IC=-3V
RS 3 0 8 ; *IPSP*
*
.PROBE
.TRAN 100.000N 100.000U 50.000U 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END
 Parametrii afisati:
• Tensiunea de iesire, V(3)
• Tensiunea pe inductanta L, V(2)

• Curentul prin inductanta L, I(l)

 Convertorul Cuk
Schema convertorului Cuk este urmatoarea:

La convertoarele analizate la punctele anterioare, forma de undă a curentului de intrare/ieșire, în mod de

conducție continuă, pentru riplu ΔIO << IO, este aproximativ dreptunghiulară la cel puțin unul din porturile convertorului:
intrare – la convertorul Buck, ieșire – la convertorul Boost sau ambele – la Buck-Boost. Astfel, pentru portul la care apare
această situație trebuie folosit un filtru foarte eficient. La convertorul Cúk, atât la intrare cât și la ieșire curentul nu are
discontinuități, are riplul ΔIO << IO, astfel încât cerințele impuse filtrului sunt mai reduse.

Functionarea convertorului Cuk:

Tensiunea la ieșirea acestui tip de convertor este negativă, ca și în cazul convertorului BuckBoost. Ținând cont
că, în regim permanent de funcționare, valoarea medie a tensiunilor pe inductanțele L1 și L2 este zero și că C1 are o
valoare suficient de mare astfel încât tensiunea pe el să poată fi considerată constantă, putem scrie relația: UC1 = UI – UO.

Astfel, UC1 este mai mare decât oricare dintre tensiunile de intrare sau de ieșire, ținând cont că tensiunea de
ieșire este negativă.

• În intervalul (0, DT), Conduce XSW. Curentul iL1 crește, iar în L1 se acumulează energie. Tensiunea de pe
condensatorul C1 polarizează invers dioda XD și, deoarece UC1>UO în valoare absolută, C1 se descarcă prin XSW
transferând energie sarcinii RS și inductanței L2 . Astfel, crește și iL2.
• În intervalul (DT,T) XSW este în blocare. Prin diodă XD circulă atât curentul iL1 cât și curentul iL2. În
condensatorul C1 se transferă energie atât din L1, cât și de la sursa de alimentare U1. Curentul iL1scade,
deoarece UC1>U1. Energia inmagazinată în L1 este transferată în RS și în condensatorul de filtraj C, astfel încât și
iL2 scade.

Putem concluziona că elementul prin care se face transferul de energie de la intrare la ieșire este condensatorul
C1: pe intervalul (DT, T) acesta primește energie din sursă de intrare și din L1, iar pe intervalul (0, DT) o cedează sarcinii și
condensatorului de filtraj.

Prezența inductanțelor L1 și L2 în serie cu sursă de alimentare, respectiv cu sarcină, asigură continuitatea atât a
curentului absorbit din sursă de alimentare cât și a celui debitat în sarcină.
 Fișierul de circuit corespunzător:
* Modelul convertorului Cuk
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8u FALL=0.1u PW=0.1u T=10u
* Sursa de tensiune care impune factorul de comandă D
VCNTL 10 0 DC .333V
XLOGIC 10 0 11 PWM_RAMP
VI 1 0 10V
L1 1 2 1mH IC=0.4A
XSW 2 0 11 0 SWITCH
C1 2 3 5uF IC=14.2V
XD 3 0 SW_DIODE_WITH_SNUB
L2 4 3 1mH IC=0.84A
C 4 0 500uF IC=-4.2V
*
RS 4 0 5
.PROBE
.TRAN 100.000n 100.000u 0 100.000n UIC
.OPTIONS ITL5 = 0
.END

Fișierul de circuit corespunzător circuitului BB_DCM.CIR:

* Modelul convertorului Cuk
.LIB C:\PSPICE\L6\L6.LIB
.PARAM RISE=9.8U FALL=0.1U PW=0.1U PERIOD=10U
*
VCNTL 50 0 DC .333V
XLOGIC 50 0 52 PWM_RAMP

*
VI 1 0 10V
L1 1 2 1mH IC=0.4A
XSW 2 0 52 0 SWITCH
C1 2 3 5U IC=14.2V
XD 3 0 SW_DIODE_WITH_SNUB
L2 4 3 1MH IC=0.84A
C 4 0 500uF IC=-4.2V
*
RS 4 0 5
.PROBE
.TRAN 100.000N 100.000U 0 100.000N UIC ; *IPSP*
.OPTIONS ITL5 = 0 ; *IPSP*
.END
 Parametrii afisati:

• Curentul prin inductanta L1, I(l1)

• Curentul prin inductanta L2, I(l2)
• Tensiunea pe condensatorul C1, V(2,3)

• Curentul prin inductanta L1, I(l1)

• Tensiunea pe inductanta L1, V(1,2)

• Curentul prin inductanta L2, I(l2)

• Tensiunea pe inductanta L2, V(4,3)
• Curentul prin condensatorul C1, I(C1)